Ekainyah,
If you're having trouble setting up your logon script via GPOs perhaps you should look at an alternative method for deploying this script.

For example:

Logon script and KIX executable file locations should be..
File Location: C:\WINNT\SYSVOL\sysvol\damain.name\scripts\

Place the following text in your User Account's Properties
User Account properties>Profiles TAB>Logon Script>"kix32.exe logon.kix"

When logging in, your user's accounts will automatically run the "kix32.exe logon.kix" command from the closest domain controller's NETLOGON share.

If you have many user accounts that you need to change this value on and want to automate the process, you can use a kix script on your Domain Controller that will make the appropriate change for you. (be sure to test this in your environment before running on production servers)

Code:
 CLS
BREAK ON
; change DomainString to match your organization's NetBIOS domain name
$DomainString='Domain'
; change GroupString to equal the appropriate security group to affect
$GroupString='TEST'
$GroupObj = GetObject('WinNT://' + $DomainString + '/' + $GroupString)
For each $UserObj in $GroupObj.Members
;Look for the word NTLOGON in case of NTLOGON OR NTLOGON.BAT
;(change NTLOGON string if different in your environment)
IF $UserObj.AccountDisabled<>'True' AND INSTR($UserObj.LoginScript,'NTLOGON')
?$UserObj.Name
?$UserObj.FullName
$UserObj.LoginScript = 'WKIX32.EXE LOGON.KIX'
$UserObj.SetInfo
$error=@error
$logshare='H:'
$logfile=$logshare+'\'+$DomainString+'CHANGESCRIPT.CSV'
$logdata=$UserObj.Name+','+$UserObj.FullName+','+$error+@CRLF
LOGGER($logfile,$logdata)

ENDIF
Next
?'--'
?'Script complete'
SLEEP 4

FUNCTION LOGGER($logfil,$logdat)
$result=0
$n=0
DO
$result=Open(1, $logfil, 5)
IF $result<>0
IF $n=0
;First wait
?'Please wait'
ELSE
;follow waits
'.'
ENDIF
SLEEP 3
ELSE
$result=WriteLine(1, $logdat)
$result=Close(1)
ENDIF
$n=$n+1
UNTIL $result=0 OR $n=5
ENDFUNCTION

_________________________
let the wise listen and add to their learning,
and let the discerning get guidance- Proverbs 1:5