You are not logged in. [Log In] KiXtart.org website » Forums » KiXtart » Lounge » Please Help
Register User       Forum List       Calendar       FAQ
Page 2 of 3 <123>
Topic Options
#98667 - 2003-02-21 06:23 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
So i can put that in the kixtart.kix script at logon?

The code that is stated on that link
Top
#98668 - 2003-02-21 06:29 PM Re: Please Help
Les Offline
KiX Master
*****

Registered: 2001-06-11
Posts: 12734
Loc: fortfrances.on.ca
Don't mean to slam you with RTFF, but there is a lot of good information there in a little space.

Start with this one:

Topic: How to use UDFs
_________________________
Give a man a fish and he will be back for more. Slap him with a fish and he will go away forever.

Top
#98669 - 2003-02-21 06:34 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
OK I get that,
Here is the code I am trying to display that I have stored in MY Computer Information.kix, maybe you know of an easier way to have this work.

I want the user to be able to double-click this and have it run when they call us for help desk.
code:
;**** Created with KiXscripts Editor | http://KiXscripts.com ****
;**** Last Modified on 2/21/2003 at 11:59:03 AM by mmontgomery ****

; *** File Name:     MYCOMP.KIX *** v1.3
; *** Date Created: 2002-03-05 by Ron Lewis
; *** Last Date Modified: 2002-10-01 11:20 PST - By Ron Lewis
; *** CHANGE: Updated for use with GetIPinfo UDF, added CPU & Speed, and Low disk space warning.
; ***         Removed the amount of days, SMS ID, USER SID so that all info would fit on 800x600
; *** Comments:	This file is called by a shortcut on the users desktop.
; *** Acknowledgments: Thanks to the following for help and ideas
; *** Shawn, Bryce, Fabian, bleonard, and Howard Bullock


Break On
$IPaddr = EnumIPInfo(0,0)
If $IPaddr = "0.0.0.0" OR $IPaddr = ""
  $IPinfo = GetIPinfo()
  $IPaddr = $IPinfo[0]
  $SNmask = $IPinfo[1]
  $Gateway = $IPinfo[2]
Else
  $SNmask = EnumIPInfo(0,1)
  $Gateway = EnumIPInfo(0,3)
EndIf

$nul = SetConsole("hide")
$HKLMAppPaths = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths"
; CheckIE variables
  Dim $RC1, $RC2, $RC3, $TmpLen1, $TmpLen2, $TmpLen3
  Dim $IEBuild, $IEFullVer, $IEMajor, $IEMinor, $IESubBd, $IEVer, $IECustom, $IEName

While @error = 0
	$app = EnumKey("$HKLMAppPaths\",$index) $index = $index + 1
	Select
		Case $app = "excel.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Excelver = GetFileVersion("$path\$app","Productversion")
		Case $app = "winword.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Wordver = GetFileVersion("$path\$app","Productversion")
		Case $app = "powerpnt.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$PowerPointver = GetFileVersion("$path\$app","Productversion")
		Case $app = "msaccess.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Accessver = GetFileVersion("$path\$app","Productversion")
		Case $app = "mspub.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Publisherver = GetFileVersion("$path\$app","Productversion")
		Case $app = "winproj.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Projectver = GetFileVersion("$path\$app","Productversion")
		Case $app = "visio32.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Visiover = GetFileVersion("$path\$app","Productversion")
		Case $app = "outlook.exe"
			$path = ReadValue("$HKLMAppPaths\$app","path")
			$Outlookver = GetFileVersion("$path\$app","Productversion")
	EndSelect
Loop

$Ex=$Excelver
$Wo=$Wordver
$Po=$PowerPointver
$Ac=$Accessver
$Pu=$Publisherver
$Pr=$Projectver
$Vi=$Visiover
$Ou=$Outlookver

Gosub "CheckIE"

$DiskSpace = GetDiskSpace("C:\") /1024
$RequiredSpace="200"
If $DiskSpace < $RequiredSpace
	$Low="WARNING! - WARNING!	: Disk space on your C: drive is low"
Else
	$Low=""
EndIf
$DaysLeft=365-@ydayno
$rc=""
$MyCPU=""
$MySpeed=Val(@MHZ)
$Mem = MemorySize()
If $MySpeed < 1001
	$MySpeed=("$MySpeed Mhz")
Else
	$MySpeed=("$MySpeed Ghz")
EndIf
If @INWIN=1	; Windows NT systems
	$MyCPU="CPU			: "+@CPU +"   "+$MySpeed
	$IsAdmin=""
	Select
		Case InGroup("\\@WKSTA\Administrators") = 1
			$IsAdmin="Yes"
		Case 1
			$IsAdmin="No"
	EndSelect
	$rc="Administrator		: "+$IsAdmin
EndIf


$SMS_ID=ReadValue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\SMS\Client\configuration\Client Properties\","SMS Unique Identifier")
$pass_age=60-@pwage

;	Message Box Display Section				
$HDNumber = MessageBox("
Help Desk Support Number	: 302-855-7898
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
My User Logon ID		: @UserID
Full Name			: @FULLNAME
Operating System		: @PRODUCTTYPE Build @BUILD
Service Pack Level		: @CSD
$MyCPU
Memory Size		: $Mem MB
$rc
Current Workstation Time	: @TIME
Available Drive Space On C:   : $DiskSpace  MB
$Low
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
My Computer Name		: @WKSTA
Computer DNS Name	: @HOSTNAME
IP Address		: $IPaddr
Subnet Mask		: $SNmask
Default Gateway		: $Gateway
MAC Address		: @address
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Days Until Password Expires	: $pass_age
Password Age		: @PWAGE
Logon Domain		: @domain
Logon Server		: @LSERVER
Primary NT Group		: @PRIMARYGROUP
Home Directory		: @HOMEDIR
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Microsoft Office:
Access			: $Ac     
Excel			: $Ex     
Internet Explorer		: $IEFullVer   $IEName
Outlook			: $Ou     
PowerPoint		: $Po     
Project			: $Pr     
Publisher			: $Pu 
Visio			: $Vi     
Word			: $Wo     
" ,"My Computer Information",262208,0)
Goto end

:CheckIE
; REM **  Confirm Internet Explorer installed on system  (See MS TechNet article Q164539)
; REM **  Format of IE Version numbers: x.xx.xxxx.xxxx  (Major.Minor.Build.SubBuild)
  $RC1 = ReadValue ("HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer", "Build")		; REM **  IE3 onward  (s/b build only, or xxxxx.xxxx)
  $RC2 = ReadValue ("HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer", "Version")	; REM **  IE4 or later only  (s/b xx.xx.xxxx.xxxx)
  $RC3 = ReadValue ("HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer", "IVer")		; REM **  IE3 only  (s/b xxx)
  $IECustom = ReadValue ("HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer", "CustomizedVersion")	; REM **  IE4 or later only: (IC = Internet Content Provider IS = Internet Service Provider CO = Corporate Administrator )
  $TmpLen1 = Len ($RC1)
  $TmpLen2 = Len ($RC2)
  $TmpLen3 = Len ($RC3)

Select
    Case ($TmpLen1 = 5) AND (SubStr ($RC2, 4, 1) = ".")		; REM **  IE6 (WinXP) - MS error w/IE 6 where minor id is single charcter, and build value only 5 characters
      $IEMajor = SubStr ($RC2, 1, 1)
      $IEMinor = SubStr ($RC2, 3, 1) + "0"
      $IEBuild = SubStr ($RC2, 5, 4)
      $IESubBd = SubStr ($RC2, 10, $TmpLen2-9)
      $IEFullVer = $IEMajor + "." + $IEMinor + "." + $IEBuild + "." + $IESubBd
    Case ($TmpLen1 = 10) AND (SubStr ($RC2, 4, 1) = ".")	; REM **  IE6 (Win2K) - MS error w/IE 6 where minor id is single charcter
      $IEMajor = SubStr ($RC2, 1, 1)
      $IEMinor = SubStr ($RC2, 3, 1) + "0"
      $IEBuild = SubStr ($RC2, 5, 4)
      $IESubBd = SubStr ($RC2, 10, $TmpLen2-9)
      $IEFullVer = $IEMajor + "." + $IEMinor + "." + $IEBuild + "." + $IESubBd
    Case ($TmpLen1 = 14) OR ($TmpLen2 >= 11)			; REM **  IE5/IE4 - 14 is MS error w/IE 5.01 SP1 for Win2K, >=11 for various IE4, 5 versions not 14-character
      $IEFullVer = $RC2
      $IEMajor = SubStr ($RC2, 1, 1)
      $IEMinor = SubStr ($RC2, 3, 2)
      $IEBuild = SubStr ($RC2, 6, 4)
      $IESubBd = SubStr ($RC2, 11, $TmpLen2-9)
    Case ($TmpLen1 >= 3) AND ($RC3 = "103")			; REM **  IE3 - the build number only
      $IEMajor = "4"
      $IEMinor = "70"
      $IEBuild = "$RC1"
      $IESubBd = ""
      $IEFullVer = $IEMajor + "." + $IEMinor + "." + $IEBuild
    Case (1)
      $Status = $Skip
      $wri = WriteLine (1, "Verified IE not installed." + $CR)
      Return
  EndSelect

; REM **  Determine exact version installed on system, (See MS TechNet article Q164539)
  Select
    Case ($IEFullVer >= "6.00.2600.0000")	$IEVer = "6.00"		$IEName="Internet Explorer 6"
    Case ($IEFullVer >= "6.00.2479.0006")	$IEVer = "6.00"		$IEName="Internet Explorer 6 Public Preview (Beta) Refresh"
    Case ($IEFullVer >= "6.00.2462.0000")	$IEVer = "6.00"		$IEName="Internet Explorer 6 Public Preview (Beta)"
    Case ($IEFullVer >= "5.50.4807.2300")	$IEVer = "5.50 SP2"	$IEName="Internet Explorer 5.5 Service Pack 2"
    Case ($IEFullVer >= "5.50.4522.1800")	$IEVer = "5.50 SP1"	$IEName="Internet Explorer 5.5 Service Pack 1"
    Case ($IEFullVer >= "5.50.4308.2900")	$IEVer = "5.50"		$IEName="Internet Explorer 5.5 Advanced Security Privacy Beta"
    Case ($IEFullVer >= "5.50.4134.0600")	$IEVer = "5.50"		$IEName="Internet Explorer 5.5"
    Case ($IEFullVer >= "5.50.4134.0100")	$IEVer = "5.50"		$IEName="Internet Explorer 5.5		(Windows Me - 4.90.3000)"
    Case ($IEFullVer >= "5.50.4030.2400")	$IEVer = "5.50"		$IEName="Internet Explorer 5.5 & Internet Tools Beta"
    Case ($IEFullVer >= "5.50.3825.1300")	$IEVer = "5.50"		$IEName="Internet Explorer 5.5 Developer Preview (Beta)"
    Case ($IEFullVer >= "5.00.3315.1000")	$IEVer = "5.01 SP2"	$IEName="Internet Explorer 5.01 SP2	(Windows 2000)"
    Case ($IEFullVer >= "5.00.3314.2101")	$IEVer = "5.01 SP2"	$IEName="Internet Explorer 5.01 SP2	(Windows 95/98 and Windows NT 4.0)"
    Case ($IEFullVer >= "5.00.3105.0106")	$IEVer = "5.01 SP1"	$IEName="Internet Explorer 5.01 SP1	(Windows 95/98 and Windows NT 4.0)"
    Case ($IEFullVer >= "5.00.3103.1000")	$IEVer = "5.01 SP1"	$IEName="Internet Explorer 5.01 SP1	(Windows 2000)"
    Case ($IEFullVer >= "5.00.2920.0000")	$IEVer = "5.01"		$IEName="Internet Explorer 5.01 	(Windows 2000, build 5.00.2195)"
    Case ($IEFullVer >= "5.00.2919.6307")	$IEVer = "5.01"		$IEName="Internet Explorer 5.01	(Also included with Office 2000 SR-1)"
    Case ($IEFullVer >= "5.00.2919.3800")	$IEVer = "5.01"		$IEName="Internet Explorer 5.01	(Windows 2000 RC2, build 5.00.2128)"
    Case ($IEFullVer >= "5.00.2919.800")	$IEVer = "5.01"		$IEName="Internet Explorer 5.01	(Windows 2000 RC1, build 5.00.2072)"
    Case ($IEFullVer >= "5.00.2516.1900")	$IEVer = "5.01"		$IEName="Internet Explorer 5.01 	(Windows 2000 Beta 3, build 5.00.2031)"
    Case ($IEFullVer >= "5.00.2614.3500")	$IEVer = "5.00"		$IEName="Internet Explorer 5		(Windows 98 Second Edition)"
    Case ($IEFullVer >= "5.00.2314.1003")	$IEVer = "5.00"		$IEName="Internet Explorer 5 		(Office 2000)"
    Case ($IEFullVer >= "5.00.2014.0216")	$IEVer = "5.00"		$IEName="Internet Explorer 5"
    Case ($IEFullVer >= "5.00.0910.1309")	$IEVer = "5.00"		$IEName="Internet Explorer 5 Beta 	(Beta 2)"
    Case ($IEFullVer >= "5.00.0518.10")		$IEVer = "5.00"		$IEName="Internet Explorer 5 Developer Preview (Beta 1)"
    Case ($IEFullVer >= "4.72.3612.1713")	$IEVer = "4.01 SP2"	$IEName="Internet Explorer 4.01 Service Pack 2 (SP2)"
    Case ($IEFullVer >= "4.72.3110.8")		$IEVer = "4.01 SP1"	$IEName="Internet Explorer 4.01 Service Pack 1 (SP1)"
    Case ($IEFullVer >= "4.72.2106.8")		$IEVer = "4.01"		$IEName="Internet Explorer 4.01"
    Case ($IEFullVer >= "4.71.1712.6")		$IEVer = "4.00"		$IEName="Internet Explorer 4.0"
    Case ($IEFullVer >= "4.71.1008.3")		$IEVer = "4.00"		$IEName="Internet Explorer 4.0 Platform Preview 2.0 (PP2)"
    Case ($IEFullVer >= "4.71.544")			$IEVer = "4.00"		$IEName="Internet Explorer 4.0 Platform Preview 1.0 (PP1)"
    Case ($IEFullVer >= "4.70.1300")		$IEVer = "3.02"		$IEName="Internet Explorer 3.02 and 3.02a"
    Case ($IEFullVer >= "4.70.1215")		$IEVer = "3.01"		$IEName="Internet Explorer 3.01"
    Case ($IEFullVer >= "4.70.1158")		$IEVer = "3.00"		$IEName="Internet Explorer 3.0 	(OSR2)"
    Case ($IEFullVer >= "4.70.1155")		$IEVer = "3.00"		$IEName="Internet Explorer 3.0"
    Case ($IEFullVer >= "4.40.520")			$IEVer = "2.00"		$IEName="Internet Explorer 2.0"
    Case ($IEFullVer >= "4.40.308")			$IEVer = "1.00"		$IEName="Internet Explorer 1.0		(Plus!)"
  EndSelect
Return

Function GetIPinfo()
	Dim $IPinfo[3], $file, $RC, $Line, $pos, $Loop
	If Open(1,"%TEMP%\"+@WKSTA+".LOG", 5)= 0
		$out = WriteLine(1, "Gathering IP info using GetIPinfo()")
		$x = Close(1)
	EndIf
	$file = "%TEMP%\"+@WKSTA+".LOG"
	If @inwin=1
		Shell "%comspec% /c ipconfig >$file"
	Else
		Shell "winipcfg /batch $file"
	EndIf
	$RC = Open(5, "$file", 2)
	If $RC = 0
		$Line=ReadLine(5)
		$Loop = 1
		While (@ERROR = 0 AND $Loop = 1)
			If InStr($Line, ". . . : ") > 0
				While (@ERROR = 0 AND $Loop = 1)
					Select
						Case InStr($Line, "IP Address") > 0
							$pos = InStr($Line, ":")
							$IPinfo[0] = SubStr($Line, $pos+2, 15)
						Case InStr($Line, "Subnet Mask") > 0
							$IPinfo[1] = SubStr($Line, $pos+2, 15)
						Case InStr($Line, "Default Gateway") > 0
							$IPinfo[2] = SubStr($Line, $pos+2, 15)
							If $IPinfo[2] <> "0.0.0.0" AND $IPinfo[2] <> ""
								$Loop = 0
							EndIf
					EndSelect
					$Line=ReadLine(5)
				Loop
			EndIf
			$Line=ReadLine(5)
		Loop
		$RC=Close(5)
	EndIf
	$GetIPinfo = $IPinfo
EndFunction

:end
Exit(0)

Top
#98670 - 2003-02-21 06:44 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
Since you are deploying a diagnostic tool, you would want the script AND kix32 on the client.

copy kix32.exe to the client
copy the computer info.kix to the client.
copy a shortcut to the client desktop

look for WSHShortcut() in the UDF forum to programatically create the shortcut.

you can't copy the same file of kix32 that is currently running your script, so you will need a second copy to copy.
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98671 - 2003-02-21 06:46 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
Exactly, that is what I have been trying to do but cannot figure it out.
Top
#98672 - 2003-02-21 06:54 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
ok... is there a language barrier?

can you code the line to COPY kix32.exe to the client somewhere, that you want it to go (keep in mind file/directory permissions and the version of kix32 you are copying cannot be in use at the time).

Show me that and I'll get back with you... or are you asking us to write it for you?

If you want us to write it for you, you will need to provide more info.
Are your users local admin?
Do you have premission to create folders in the netlogon shares or do you have a file repository that your users can read from?
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98673 - 2003-02-21 06:59 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
Ok the domain users are mostly power users.

I have a second copy of the kix32 in a directory separate from the one that is being used.

The \\sussex1\netlogon all domain users can access fine. They cannot create folders there obviously but that is where the my computer information.kix script file is. The second copy of the kix32.exe file is in a subdirectory under netlogon called "Client Shortcut".

If this is enough information to help you write it that would be great or at least write the code and make comments in there what info you still need.

Thanks

I am going to lunch to step away from this. I have been at it all morning.

Thanks for the help.
Top
#98674 - 2003-02-21 07:25 PM Re: Please Help
Jack Lothian Offline
MM club member
*****

Registered: 1999-10-22
Posts: 1169
Loc: Ottawa,Ontario, Canada
I am not sure what you are asking. You started out with a question concerning deploying & copying kix to clients, then you moved to questions about creating & copying a shortcut & finally the script posted doesn't deal with either of these issues??

In the posted script what is the exact problem. Maybe you could state the problem more explicitly.

PS: Maybe I am thickheaded but after your last post I still don't understand the nature of your problem. I suspect you have more than 1 problem & you are mixing them together.

[ 21. February 2003, 19:30: Message edited by: Jack Lothian ]
_________________________
Jack

Top
#98675 - 2003-02-21 07:41 PM Re: Please Help
Les Offline
KiX Master
*****

Registered: 2001-06-11
Posts: 12734
Loc: fortfrances.on.ca
Jack,
If I may annswer for DJ, yes he wants to deploy KiX to the WKSTA, and yes he wants to create a shortcut on the desktop, all in an effort to use NTDOC's script that he posted.

He also wants information on deploying to Wintendos.

Add to that, he want information on deploying GPO scripts as he does not want to use legacy logon scripts which require that every users' profile be configured.

Yes this is a lot to ask in one thread, and replies can be expected to diverge to cover the individual aspects.

DJ,
If I may, I would suggest that you break your requests into bite-sized pieces and start separate threads for each of them. Also, 'general discussions' is probably not the best place to post these to. Take a moment to familiarize youself with board etiquette by reading ABC's of KiXtart board etiquette... and then post starters type questions to 'starters' and post actual scripts to discuss to 'scripts'. I realize that you probably have a lot on your plate right now, but it will pay off to take some time to read the FAQs instead of spinning your wheels. Unfortunately we have not been able to cover everything in the FAQs, so using the search tool is essential to getting the best information. Better that posting a question and receiving the 'answer du jour'.
_________________________
Give a man a fish and he will be back for more. Slap him with a fish and he will go away forever.

Top
#98676 - 2003-02-21 07:55 PM Re: Please Help
Jack Lothian Offline
MM club member
*****

Registered: 1999-10-22
Posts: 1169
Loc: Ottawa,Ontario, Canada
Les,

That may be but I believe the first 2 threads I gave all gave examples of Batch portions of the script to deploy kixtart. I believe Bryce's example will work for all OS. The last thread does contain a debate between but it also discusses several approaches to solving the problem with links to other threads. Yet he says this is BS? My guess is he wasn't interested in this issue.

Finding info on creating shortcuts is easy if one follows any of the suggestions given on this topic.

Also, his discussions seems to indicate he hasn't read some of the specialized info concerning Win9x in the manual.

Final point, Ballistic,

With Win9x machines you can not work with the HKCU hive during logon. It must be accessed through a separate script activated through the runonce key.

[ 21. February 2003, 19:56: Message edited by: Jack Lothian ]
_________________________
Jack

Top
#98677 - 2003-02-21 07:56 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
Ok i will start new posts.
Top
#98678 - 2003-02-21 08:01 PM Re: Please Help
Les Offline
KiX Master
*****

Registered: 2001-06-11
Posts: 12734
Loc: fortfrances.on.ca
Jack,
I think DJ's use of the term 'BS' was just a poor choice of words. One asking for free advice generally would not want to alienate those that are taking time out of their busy workday to help.

You could demand an apology but I simply wrote it off as frustration brought on by workload and overwhelming information.

[ 21. February 2003, 20:02: Message edited by: LLigetfa ]
_________________________
Give a man a fish and he will be back for more. Slap him with a fish and he will go away forever.

Top
#98679 - 2003-02-21 08:15 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
I am putting my new posts in "Scripts"
Anyone that has been following this post that wishes to help me out it would be greatly appreciated.

Thanks In Advance.
Top
#98680 - 2003-02-21 09:39 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
on your machine (desktop) create a folder called c:\kixscripts

in that folder, copy kix32.exe and 'My Computer Info.kix'

in that folder create a shortcut to c:\kixscripts\kix32.exe

edit the shortcut and modify the target path to c:\kixscripts\kix32.exe "c:\kixscripts\My Computer Info.kix"

be sure to include the quotes.

test and verify the shortcut works.

let me know that this part works.
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98681 - 2003-02-21 10:18 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
Once you have a verified good shortcut, copy that to your 'netlogon\Client Shortcut' folder.

move the 'my computer information.kix' script into that folder also

end of stage 2.
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98682 - 2003-02-21 10:28 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
in your logonscript put in these lines:

code:
 
md c:\kixscripts
if not exist('c:\kixscripts\kix32.exe')
copy \\sussex1\netlogon\Client Shortcut\kix32.exe' 'c:\kixscripts'
endif
if not exist('c:\kixscripts\my computer information.kix')
copy \\sussex1\netlogon\Client Shortcut\my computer information.kix' 'c:\kixscripts'
endif
$desktop = ReadValue("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Desktop")
if not exist('$desktop\my computer information.lnk')
copy \\sussex1\netlogon\Client Shortcut\my computer information.lnk' '$desktop'
endif
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98683 - 2003-02-21 10:29 PM Re: Please Help
Radimus Moderator Offline
Moderator
*****

Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
that will work for your nt/2k clients
win9x is a bit more complex
_________________________
How to ask questions the smart way <-----------> Before you ask

Top
#98684 - 2003-02-24 02:34 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
Ok the shortcut works and I have copied and pasted that code into my kixtart.kix logon script.

The problem with it is there must be something missing in the code because a couple of the endif's are purple instead of blue like they should be.

I am trying to figure it out. So far so good though. Thanks a ton.
Top
#98685 - 2003-02-24 02:44 PM Re: Please Help
DJ Ballistic Offline
Starting to like KiXtart

Registered: 2003-02-21
Posts: 185
Dude you rock. That works perfectly. Everything works fine for the shortcut. I even have a nice little icon associated with it that also works. Ok next problem.

You said for the 9x clients it is a little more difficult. I wish I could say I didn't have any at all on my network but we have a handfull of them. How should I go about doing that. From what I have read over the weekend it looks like I have do call the kixscript from a batch file but it can't be that easy. There is more too it I assume?
Top
#98686 - 2003-02-24 03:52 PM Re: Please Help
Jack Lothian Offline
MM club member
*****

Registered: 1999-10-22
Posts: 1169
Loc: Ottawa,Ontario, Canada
DJ,

You really should read some of the links I mentioned. Here is possible extension of Radimus script for Win9x:

code:
md c:\kixscripts
if not exist('c:\kixscripts\kix32.exe')
    copy '\\sussex1\netlogon\Client Shortcut\kix32.exe' 'c:\kixscripts'
endif
if not exist('c:\kixscripts\my computer information.kix')
    copy '\\sussex1\netlogon\Client Shortcut\my computer information.kix' 'c:\kixscripts'
endif
IF @INWIN=1
   $desktop = ReadValue("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders","Desktop")  
ELSE
    if not exist('c:\kixscripts\kx32.dll')
        copy '\\sussex1\netlogon\Client Shortcut\kx32.dll' 'c:\kixscripts'
    endif
    if not exist('c:\kixscripts\kx16.dll')
        copy '\\sussex1\netlogon\Client Shortcut\kx16.dll' 'c:\kixscripts'
    endif
    if not exist('c:\kixscripts\kx95.dll')
        copy '\\sussex1\netlogon\Client Shortcut\kx95.dll' 'c:\kixscripts'
    endif
   $desktop = 'C:\windows\desktop'
ENDIF
if not exist('$desktop\my computer information.lnk')
    copy '\\sussex1\netlogon\Client Shortcut\my computer information.lnk' '$desktop'
endif
I haven't tested this though. It is really just a conversion of the code NTDOC offered you without the COM stuff. Also, in the first link on this subject I offered you, Lonkero gives an excellant example of how to do shortcut copying with Win9x.

I don't agree with copying kix32.exe in your kix script. Ideally, you always want to ensure that only 1 version of kix exist locally & it should always be the current version. Once you start kix up you can not change it during that instance.

A better idea is to do the copying of Kix & its DLLs from a batch script just before kix is called. This way you will never have version conflicts. Here is an example by sealeopard (2nd posting) of how you might implement this.

Jen's logon.bat with kix deployment

There are other ways to do this but this is very clearly layed out. This is a link I mentioned before.

PS: For an excellant example of a full blown logon & maintenance service implemented through kix, checkout jens' (sealeopard) ksms script. You can get it by searching the scripts forum for 'ksms' or visting jens' website.

[ 24. February 2003, 16:29: Message edited by: Jack Lothian ]
_________________________
Jack

Top
Page 2 of 3 <123>


Moderator:  Arend_, Allen, Jochen, Radimus, Glenn Barnas, ShaneEP, Ruud van Velsen, Mart 
Hop to:
Shout Box

Who's Online
1 registered (Allen) and 1198 anonymous users online.
details
Newest Members
M_Moore, BeeEm, min_seow, Audio, Hoschi
17883 Registered Users
My Cookies · Mark all read Powered by UBB.threads™ Contact Us · KiXtart.org website · Top

Generated in 0.16 seconds in which 0.084 seconds were spent on a total of 13 queries. Zlib compression enabled.
Search the board with:
superb Board Search
or try with google:
Google
Web kixtart.org