quote:

---

PsFile uses the NET API, which is documented in the Platform SDK

---

code:

---

Dim $oFSO, $Resource
Dim $FileName, $ServerName
Dim $Row, $oXL
 
'Enter filename or part of filename of locked file: '
GetS $FileName
 
?'Enter servername: '
GetS $ServerName
 
? 'Checking locks for filename: ' + $FileName + ' on server: ' $ServerName
 
$oXL = CreateObject("Excel.Application")
$RC = $oXL.workbooks.add()
 
$oXL.Cells(1, 1).Value = "User"
$oXL.Cells(1, 2).Value = "Path"
 
$oFSO = GetObject("WinNT://" + $ServerName + "/LanmanServer")
 
$Row = 2
If VarTypeName($oFSO) = 'Object'
	For Each $Resource In $oFSO.Resources
		If $Resource.User <> "" And Right($Resource.User,1) <> "$"
			If InStr($Resource.Path, $FileName)
				$oXL.Cells($Row, 1).Value = $Resource.User
				$oXL.Cells($Row, 2).Value = $Resource.Path
				$Row = $Row + 1
			EndIf
		EndIf
	Next
EndIf
 
$oXL.Cells($Row + 1, 1).Value = 'Filename: ' + $FileName
$oXL.Cells($Row + 1, 2).Value = 'Number of file locks: ' + CStr($Row - 2)
$RC = $oXL.Cells.EntireColumn.Autofit
$oXL.Visible = True
 
$oXL = 0

---

code:

---

BREAK ON
DIM $oFSO, $Resource

$FORM			= CREATEOBJECT("KIXTART.FORM")
$FORM.SIZE		= 600,400
$FORM.CENTER
$FORM.CAPTION		= "Find File Locks"
$lblSERVER		= $FORM.Label("Server:")
$lblSERVER.SIZE		= 60,15
$lblSERVER.LOCATION	= 10,12
$txtSERVER		= $FORM.TextBox
$txtSERVER.SIZE		= 70,19
$txtSERVER.LOCATION	= 80,10
$lblFILE		= $FORM.Label("File Name:")
$lblFILE.SIZE		= 60,15
$lblFILE.LOCATION	= 10,42
$txtFILE		= $FORM.TextBox
$txtFILE.SIZE		= 210,19
$txtFILE.LOCATION	= 80,40
$cmdFIND		= $FORM.CommandButton("Find")
$cmdFIND.SIZE		= 60,19
$cmdFIND.LOCATION	= 160,10
$cmdFIND.ONCLICK	= "cmdFIND_CLICK()"
$cmdFIND.DEFAULT	= 1
$cmdCANCEL		= $FORM.CommandButton("Cancel")
$cmdCANCEL.SIZE		= 60,19
$cmdCANCEL.LOCATION	= 230,10
$cmdCANCEL.ONCLICK	= "$$FORM = 'NOTHING'"
$cmdCANCEL.CANCEL	= 1
$lblSTATUS		= $FORM.Label("Status:  Waiting for input")
$lblSTATUS.SIZE		= 200,15
$lblSTATUS.LOCATION	= 10,75
$lsvLIST		= $FORM.ListView
$lsvLIST.SIZE		= 575,260
$lsvLIST.LOCATION	= 10,105
$ = $lsvLIST.COLUMNS.ADD("User",100,0)
$ = $lsvLIST.COLUMNS.ADD("File",471,0)
$txtSERVER.SETFOCUS
$FORM.SHOW


WHILE $FORM.VISIBLE
	$ = EXECUTE($FORM.DOEVENTS)
LOOP


FUNCTION cmdFIND_CLICK()
	$ = $lsvLIST.ITEMS.CLEAR
	$lblSTATUS.TEXT = "Status:  Checking locks for filename " + $txtFILE.TEXT + " on server " + $txtSERVER.TEXT
	$oFSO = GetObject("WinNT://" + $txtSERVER.TEXT + "/LanmanServer")
	$CNT = 0
	IF VARTYPENAME($oFSO) = "Object"
		FOR EACH $Resource IN $oFSO.Resources
			IF $Resource.User <> "" AND RIGHT($Resource.User,1) <> "$"
				IF INSTR($Resource.Path, $txtFILE.TEXT)
					$CNT = $CNT + 1
					$ITEM = $lsvLIST.ITEMS.ADD($Resource.User)
					$ITEM.SUBITEMS(0).TEXT = $Resource.User
					$ITEM.SUBITEMS(1).TEXT = $Resource.Path
				ENDIF
			ENDIF
		NEXT
	ENDIF
	$lblSTATUS.TEXT = $txtFILE.TEXT + " : Number of file locks: " + $CNT
ENDFUNCTION

---