• start a "master"-ppt as a continues slideshow
• during show check for existence of updated "master"-ppt in a specific dir
• if exist then load a "busy updating"-ppt, put this to the foreground and stop the "master"-ppt
• Update the "master"-ppt
• if copy done then load the "master"-ppt, put this to the foreground and stop the "busy updating"-ppt

code:

---

;****************************************************************************
;
;SCRIPT        : HALVIEWER.KIX
;
;AUTHOR        : Patrick Rutten (MightyR1@hotmail.com)
;
;CONTRIBUTORS  : 
;
;ACTION        : Runs a PPS and checks for update
;                   if update found, kill PPS, copy update, run new PPS
;
;SYNTAX        : HALVIEWER.KIX
;
;VERSION       : 1.0 - Initial release
;
;PARAMETERS    : -
;
;REMARKS       : -
;
;RETURNS       : -
;
;DEPENDENCIES  : WMI, Powerpoint, KIX32, hidetbar.exe
;
;KIXTART VER   : 4.20
; 
;EXAMPLE(S)    : -
;
;KNOWN ISSUES  : -
;
;****************************************************************************
;
;
Break on
$rc=SetOption("Explicit","On")

;Declare Vars
Dim $rc, $masterpps, $updatepps, $hidetbar, $runcmd, $startcmd
Dim $sleeptime, $copytime, $killtime, $runpps

$masterpps=@scriptdir+'\master.pps'
$updatepps=@scriptdir+'\update.pps'
$hidetbar=@scriptdir+'\hidetbar.exe'
$runcmd='Run "%comspec% /c '
$startcmd='Run "%comspec% /c start '
$sleeptime=30
$copytime=3
$killtime=3
$runpps=1

;Hide Taskbar
$rc=Execute("$runcmd $hidetbar chr(34)")

;infinite loop
While 1
	Sleep $sleeptime

	;if update found: kill current, copy new, delete new
	If Exist($updatepps)
		$rc=wmikill("Powerpnt.exe")
		Sleep $killtime
		Copy $updatepps	$masterpps
		Sleep $copytime
		Del $updatepps
		Sleep $killtime
		$runpps=1
	EndIf
	
	;if runflag is 1 then start the pps
	If $runpps
		$rc=Execute("$startcmd $masterpps chr(34)")
		$runpps=0
	EndIf
Loop
Exit 0

Function WMIKill($proc_to_kill,optional $computer)
        Dim $wmistring, $wmi, $process, $processes, $kill
   If NOT $computer $computer = @WKSTA EndIf
   $wmistring = "winmgmts:{impersonationlevel=impersonate}!//" + $computer
   $wmi = GetObject($wmistring)
   If $wmi
      $processes = $wmi.instancesof("win32_process")
      For Each $process In $processes
         If $process.name = $proc_to_kill
            $kill = $process.terminate(0)
            If @ERROR = 0
               $wmi = 0
               Exit 0
            Else
               $wmi = 0
               Exit 1
            EndIf
         EndIf
      Next
   Else
      Exit 2
   EndIf
EndFunction

---