#91183 - 2003-01-27 03:19 PM
PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Jochen
KiX Supporter
Registered: 2000-03-17
Posts: 6380
Loc: Stuttgart, Germany
|
Ok,
Long time Jooel and I struggled to get this working, and finally here it is ...
Minimum Requirements : Kix 4.20 , KiXforms build 36, Wordfile.ini (Get the complete package here)
Features :
- Choose your colors for different Keyword families
- Easy Copy and Paste of Conversion to post
- Copy the code directly to the editor of your choice without loosing Indentation !!!
- Maintaining Keyword Lists programmatically
- Preview / and save as htm file
- ummmm .... It's FREE
![[Big Grin]](images/icons/grin.gif)
Following the good old tradition to post code, here it is :
; UBB PostPrep 1.0
; ----------------------------------------------------------------------------------------------
; MINIMUM REQUIREMENTS
;
; KIXTART 4.20 (WKiX32)
; KIXFORMS build 37 (2.2.0)
; ----------------------------------------------------------------------------------------------
; AUTHORs Jooel Nieminen - Conversion Engine !
; Jochen Polster - Form, Controls, Design, Codestarter
; ----------------------------------------------------------------------------------------------
; ACKNOWLEDGEMENTS Shawn Tassie (for Kixforms of course!)
; Richard Howarth (for pointing out the <br>-tag Issue)
; All KiXtart Enthusiastics for which we wrote this ![[Wink]](images/icons/wink.gif)
; ----------------------------------------------------------------------------------------------
; VERSION HISTORY 1.0 - 01/27/2003 Initial worthwhile release
;
; 0.9 A - different very buggy Alpha releases not worth to mention
;
; 0.9 P - Preview Version(s) discussed on kixtart.org Bulletin board
; ----------------------------------------------------------------------------------------------
break on
$ = setascii("on")
$ReqForms = 36
$Version = "1.0"
$Wordfile = @scriptdir + '\Wordfile.ini'
$Kix = substr(@kix,1,4)
if $Kix < "4.20"
$ = messagebox('This Script requires at least KiXtart 4.20 ','Version Check',4112)
quit()
endif
Global $SourceText[0], $TargetText[0], $Colors[7], $PathOpen, $PathSave, $ShowStatistics
$Sections = "Comments","Strings","Numbers","Commands","Functions","Macros","Operators","Variables"
if exist($Wordfile)
for $i = 0 to 7
$Colors[$i] = readprofilestring($Wordfile,$Sections[$i],"Color")
next
$CTable = split(readprofilestring($Wordfile,"ColorTable","Colors"),',')
$Commands = split(readprofilestring($Wordfile,"Commands", "words"),',')
$Functions = split(readprofilestring($Wordfile,"Functions", "words"),',')
$PathOpen = readprofilestring($Wordfile,"Global","PathOpen")
$PathSave = readprofilestring($Wordfile,"Global","PathSave")
$ShowStatistics = val(readprofilestring($Wordfile,"Global","ShowStats"))
if not ubound($Commands)
or not ubound($Functions)
or not ubound($Colors)
$ = messagebox('This Script requires a consistent wordfile','File check',4112)
quit()
endif
else
$ = messagebox('This Script requires a wordfile ','File missing',4112)
quit()
endif
$frm = createobject("Kixtart.Form")
if val($frm.Build) < $ReqForms
$ = messagebox('This Script requires Kixforms build ' + $ReqForms,'Version check',4112)
quit()
endif
$frm.Size = 810,620
$frm.Caption = "UBB Postprep " + $Version
$frm.Icon = @scriptdir + "\Kix.ico"
$frm.Center
$lblPowered = $frm.Label("Powered by", $frm.ClientWidth-98,$frm.ClientHeight-115,90,20)
$lblPowered.FontName = "Comic sans MS"
$lblPowered.FontBold = 1
$lblPowered.FontSize = 11
$lblPowered.ForeColor = Kixtart
$lblBuild = $frm.Label(" KiXtart " + $kix + @crlf
+ " and" + @crlf + " KiXforms build " + $frm.Build,
$frm.ClientWidth-98,$frm.ClientHeight-90,90,40)
$lblBuild.FontName = "Comic sans MS"
$lblBuild.FontBold = 1
$lblBuild.FontSize = 7
$lblBuild.ForeColor = Kixtart
$hypBoard = $frm.HyperLink("Bulletin Board",$frm.ClientWidth-87, $frm.ClientHeight-45, 100, 25)
$hypBoard.Value = "http://www.kixtart.org/cgi-bin/ultimatebb.cgi?Category=1"
$hypBoard.ToolTip = $hypBoard.Value
$txtSource = $frm.TextBox(,5,5)
$txtSource.Right = $frm.ClientWidth-110
$txtSource.Bottom = $frm.ClientHeight/2-3
$txtSource.ScrollBars = 3
$txtSource.AcceptsTab = 1
$txtSource.FontName = "Courier New"
$txtSource.FontSize = 8
$txtSource.MultiLine = 1
$txtSource.OnChange = "TextSource_Change()"
$txtTarget = $frm.TextBox(,5,5 + $txtSource.Bottom)
$txtTarget.Right = $frm.ClientWidth - 110
$txtTarget.Bottom = $frm.ClientHeight - 20
$txtTarget.ScrollBars = 3
$txtTarget.FontName = "Courier New"
$txtTarget.FontSize = 8
$txtTarget.MultiLine = 1
$lblStatus1 = $frm.Label("",5,$frm.ClientHeight-17,$frm.ClientWidth/3*2,15)
$lblStatus1.BorderStyle = 5
$lblStatus2 = $frm.Label("",$lblStatus1.Right+3,$frm.ClientHeight-17,$frm.ClientWidth/3-13,15)
$lblStatus2.BorderStyle = 5
$prg = $lblStatus2.ProgressBar
$prg.Size = $frm.ClientWidth/3-10,13
$prg.Style = 1
$prg.BorderStyle = 0
$prg.Value = 0
$prg.ForeColor = DarkBlue
$prg.Visible = 0
$btnOpen = $frm.Button("Open...",$txtTarget.Right+10,5,90,25)
$btnOpen.BorderStyle = 5
$btnOpen.OnClick = "btnOpen_Click()"
$btnClear = $frm.Button("Clear",$txtTarget.Right+10,$btnOpen.Bottom+2,90,25)
$btnClear.BorderStyle = 5
$btnClear.OnClick = "btnClear_Click()"
$btnClear.Enabled = 0
$btnKeyWords = $frm.Button("Keywords...",$txtTarget.Right+10,$btnClear.Bottom+2,90,25)
$btnKeyWords.BorderStyle = 5
$btnKeyWords.OnClick = "btnKeyWords_Click()"
$btnColor = $frm.Button("Set Colors...",$txtTarget.Right+10,$btnKeyWords.Bottom+2,90,25)
$btnColor.BorderStyle = 5
$btnColor.OnClick = "btnColor_Click()"
$fraFormat = $frm.Frame("Convert:",$txtTarget.Right + 9,$btnColor.Bottom + 5,92,204)
dim $Top
$Top = 17
for $i = 0 to ubound($Sections)
$ = execute("$$txtFormat$i = $$fraFormat.TextBox($$Sections[$i],6,$Top,80,20)")
$ = execute("$$txtFormat$i.Caption = $$Sections[$i]")
$ = execute("$$txtFormat$i.ForeColor = &"+readprofilestring($Wordfile,$Sections[$i],'Color'))
$ = execute("$$txtFormat$i.FontBold = -"+val(readprofilestring($Wordfile,$Sections[$i],'Bold')))
$ = execute("$$txtFormat$i.Locked = 2")
$ = execute("$$txtFormat$i.TabStop = 0")
$ = execute("$$Top = $$txtFormat$i.Bottom + 3")
next
$btnConvert = $frm.Button("Convert",$txtTarget.Right+10,$fraFormat.Bottom+10,90,25)
$btnConvert.BorderStyle = 5
$btnConvert.OnClick = "btnConvert_Click()"
$btnConvert.Enabled = 0
$btnPreview = $frm.Button("Preview...",$txtTarget.Right+10,$btnConvert.Bottom+2,90,25)
$btnPreview.BorderStyle = 5
$btnPreview.OnClick = "btnPreview_Click($$txtTarget.text)"
$btnPreview.Enabled = 0
$btnCopy = $frm.Button("Copy",$txtTarget.Right+10,$btnPreview.Bottom+2,90,25)
$btnCopy.BorderStyle = 5
$btnCopy.OnClick = "btnCopy_Click()"
$btnCopy.Enabled = 0
$btnSave = $frm.Button("Save As...",$txtTarget.Right+10,$btnCopy.Bottom+2,90,25)
$btnSave.BorderStyle = 5
$btnSave.OnClick = "btnSave_Click()"
$btnSave.Enabled = 0
$chkShowStats = $frm.CheckBox("Statistics ?",$txtTarget.Right + 10, $btnSave.Bottom + 10,100,15)
$chkShowStats.Value = $ShowStatistics
$chkShowStats.OnClick = "chkShowStats_CLick($$chkShowStats.Value)"
$btnOpen.SetFocus
$frm.Show
while $frm.Visible
$ = execute($frm.DoEvents)
loop
function btnAdd_Click()
$frmAdd = createobject("Kixtart.Form")
$frmAdd.Caption = "Add " + $cboSel.Text
$frmAdd.Size = 200,100
$frmAdd.Location = $frm.Right-400,$frm.Top+142
$frmAdd.SysMenu = 0
$txtAdd = $frmAdd.TextBox("",13,10,150,20)
$txtAdd.OnChange = "if $$txtAdd.Text <> '' and ascan($$"+$cboSel.Text+",$$txtAdd.Text)=-1 $$btnOk.Enabled=1 else $$btnOk.Enabled=0 endif"
$btnOk = $frmAdd.Button("OK",$frmAdd.ClientWidth/2-83,$frmAdd.ClientHeight-30,80,25)
$btnOk.BorderStyle = 5
$btnOk.Enabled = 0
$btnOk.OnClick = "$$=$$lvw.Items.Add($$txtAdd.Text)
redim $$"+$cboSel.Text+"[0]
for $$i=1 to $$lvw.Items.Count redim preserve $$"+$cboSel.Text+"[$$i-1] $$"+$cboSel.Text+"[$$i-1]=$$lvw.Items($$i-1).Text next
$$=writeprofilestring($$Wordfile,$$cboSel.Text,'Words',join($$"+$cboSel.Text+",','))
for each $$item in $$lvw.SelectedItems $$Item.Selected = 0 next
$$txtAdd.SetFocus $$txtAdd.Text=''"
$btnEx = $frmAdd.Button("Exit",$frmAdd.CLientWidth/2+3,$frmAdd.ClientHeight-30,80,25)
$btnEx.BorderStyle = 5
$btnEx.Cancel = 1
$btnEx.OnClick = "$$frmAdd=0"
$frmAdd.Show
$txtAdd.SetFocus
while $frmAdd.Visible
$ = execute($frmAdd.DoEvents)
loop
endfunction
function btnClear_Click()
$txtSource.Text = ''
$txtTarget.Text = ''
$lblStatus1.Text = ''
$btnSave.Enabled = 0
$btnCopy.Enabled = 0
$btnClear.Enabled = 0
$btnConvert.Enabled = 0
$btnPreview.Enabled = 0
endfunction
function btnColor_Click()
dim $Left, $Top, $index
$index = 0 $Left = 7 $Top = 19
$frmDialog1 = createobject("Kixtart.Form")
$frmDialog1.Size = 245,233
$frmDialog1.Caption = "Set Colors"
$frmDialog1.Location = $frm.Right - $frmDialog1.ClientWidth - 120 , $frm.Top + $btnColor.Bottom - 2
$frmDialog1.ForeColor = MediumBlue
$frmDialog1.DrawWidth = 2
$frmDialog1.SysMenu = 0
$cboStrings = $frmDialog1.ComboBox
$cboStrings.List = $Sections
$cboStrings.Location = 5,8
$cboStrings.ListIndex = 0
$cboStrings.Style = 1
$cboStrings.Default = 1
$cboStrings.OnClick = "$$index = cboStrings_CLick($$Index,$$cboStrings.ListIndex)"
$chkBold = $frmDialog1.CheckBox("Bold",112,11,50,15)
$chkBold.OnClick = "chkBold_Click($$index)"
$chkBold.Value = val(readprofilestring($Wordfile,$Sections[0],"Bold"))
$btnClose1 = $frmDialog1.Button("Close",$frmDialog1.ClientWidth-75,7,70,25)
$btnClose1.BorderStyle = 5
$btnClose1.Cancel = 1
$btnClose1.OnClick = "$$frmDialog1=0"
$fraColor = $frmDialog1.Frame("Colors:",5,40,230,163)
for $i = 0 to ubound($CTable)
$ = execute("$$lblColor$i = $$fraColor.Label('',$Left,$Top,20,18)")
$ = execute("$$lblColor$i.BorderStyle = 2")
$ = execute("$$lblColor$i.BackColor = &" + $CTable[$i])
$ = execute("$$lblColor$i.OnClick = 'Color_Change($$$$index,$i)'")
$Left = $Left + 28
if $Left = 231
$Left = 7
$Top = $Top + 24
endif
next
$e = ascan($CTable, $Colors[$index])
$ = execute("$$frmDialog1.Rectangle($$lblColor$e.Left+3,$$lblColor$e.Top+38,24,22)")
$frm.Enabled = 0
$frmDialog1.Show
while $frmDialog1.Visible
$ = execute($frmDialog1.DoEvents)
loop
$frm.Enabled = 1
endfunction
function btnConvert_Click()
dim $StartTime, $EndTime, $HColors[7], $out, $i,$fb
$txtSource.Locked = 2
$frm.MousePointer = 11
$prg.Visible = 1
$btnOpen.Enabled = 0
$btnKeyWords.Enabled = 0
$btnColor.Enabled = 0
$btnPreview.Enabled = 0
$btnCopy.Enabled = 0
$btnSave.Enabled = 0
$btnClear.Enabled = 0
for $i = 0 to ubound($Colors)
$HColors[$i] = right($Colors[$i],2) + substr($Colors[$i],3,2) + left($Colors[$i],2)
$ = execute("$$fb=''+$$fb+$$txtFormat$i.FontBold+' '")
next
$fb=split(left($fb,len($fb)-1))
$StartTime = @time + ':' + @msecs
$out = kix2htm($txtSource.Text,$HColors,$fb,$Functions,$Commands)
$EndTime = @time + ':' + @msecs
$txtTarget.Text = $out[0]
$txtSource.Locked = 0
$frm.MousePointer = 0
$prg.Value = 0
$btnCopy.Enabled = 1
$btnPreview.Enabled = 1
$btnSave.Enabled = 1
$btnClear.Enabled = 1
$btnOpen.Enabled = 1
$btnKeyWords.Enabled = 1
$btnColor.Enabled = 1
$prg.Visible = 0
if $ShowStatistics
$ = ShowStats(DeltaTime($StartTime, $EndTime), $out[3], $out[4], $out[2], $out[1])
endif
endfunction
function btnCopy_Click()
$txtTarget.SelStart = 0
$txtTarget.SelLength = -1
$txtTarget.Copy
endfunction
function btnDel_Click()
dim $
if $lvw.SelectedItems.Count > 0 and $lvw.FocusedItem.Selected
$lvw.SelectedItems.clear
$ = execute("redim $$"+$cboSel.Text+"[0]")
for $i = 1 to $lvw.Items.Count
$=execute("redim preserve $$"+$cboSel.Text+"[$$i-1] $$"+$cboSel.Text+"[$$i-1]=$$lvw.Items($$i-1).Text")
next
$ = execute("$$=writeprofilestring($$Wordfile,$$cboSel.Text,'Words',join($$"+$cboSel.Text+",','))")
endif
endfunction
function btnKeyWords_Click()
dim $frmDialog2
$frm.Enabled = 0
$frmDialog2 = createobject("Kixtart.form")
$frmDialog2.Size = 400,380
$frmDialog2.Caption = "Maintain Keywords"
$frmDialog2.Location = $frm.Right-$frmDialog2.ClientWidth-120,$frm.Top+$btnKeyWords.Bottom-2
$frmDialog2.SysMenu = 0
$cboSel = $frmDialog2.ComboBox
$cboSel.List = "Commands","Functions"
$cboSel.Location = 5,8
$cboSel.ListIndex = 0
$cboSel.Style = 1
$cboSel.OnClick = "cboSel_Click()"
$btnAdd = $frmDialog2.Button("Add Keywords...",$cboSel.Right+5,5,95,25)
$btnAdd.BorderStyle = 5
$btnAdd.OnCLick = "btnAdd_Click()"
$btnDel = $frmDialog2.Button("Delete Selected",$btnAdd.Right+5,5,95,25)
$btnDel.BorderStyle = 5
$btnDel.OnClick = "btnDel_Click()"
$btnClose2 = $frmDialog2.Button("Close",$frmDialog2.ClientWidth-75,5,70,25)
$btnClose2.BorderStyle = 5
$btnClose2.Cancel = 1
$btnClose2.OnClick = "$$frmDialog2=0"
$lvw = $frmDialog2.ListView()
$lvw.Left = 5
$lvw.Top = 35
$lvw.Right = $frmDialog2.ClientWidth-5
$lvw.Bottom = $frmDialog2.ClientHeight-5
$lvw.View = 2
$lvw.Gridlines = True
$lvw.MultiSelect = True
$lvw.Sorted = 1
for $i = 0 to ubound($Commands)
$ = $lvw.Items.Add($Commands[$i])
next
for each $Item in $lvw.SelectedItems
$Item.Selected = 0
next
$frmDialog2.Show
while $frmDialog2.Visible
$=execute($frmDialog2.DoEvents)
loop
$frm.Enabled = 1
endfunction
_________________________
|
|
Top
|
|
|
|
#91185 - 2003-01-27 03:27 PM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Jochen
KiX Supporter
Registered: 2000-03-17
Posts: 6380
Loc: Stuttgart, Germany
|
|
|
Top
|
|
|
|
#91186 - 2003-01-27 03:43 PM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Radimus
Moderator
Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
|
break on
$=setconsole("hide")
;$merlin_path = "%windir%\msagent\chars\merlin.acs"
;$agent = createobject ("agent.control.2")
;$agent.connected= "1"
;$= $agent.characters.load("merlin","$merlin_path")
;$merlin = $agent.characters.character("merlin")
$KPingerRegKey='HKEY_CURRENT_USER\Software\KPinger'
Global $ButtonArray0[0]
$row = 5 $col = 5
$hoff = 1 $voff = 10
$hsize = 20 $vsize = 20
$Form = CreateObject("Kixtart.Form")
$yres = $Form.screen.height
$Form.Size = 1,1
$Form.left = 0
$Form.Text = "KPinger"
$Form.MinButton = 0
$Form.borderstyle = 0
$Form.top = $yres-taskbar()+3-$Form.height
$=tb("New Server" ,0,0,12) $Server1.onClick = "add()"
$=tb("End Program",1,0,37) $Server2.onClick = "end()"
$Index = 0
$ValueName = ENUMVALUE("$KPingerRegKey", $Index)
While @ERROR = 0
$nextbutton=ubound($buttonarray0)+1
$=tb($ValueName,$nextbutton,0,32)
$Index = $Index + 1
$ValueName = ENUMVALUE("$KPingerRegKey", $Index)
Loop
$timer=$form.timer(60*1000)
$timer.ontimer='pingarray()'
$Form.Show
While $Form.Visible
$= Execute($Form.DoEvents)
Loop
Exit 1
: ****************************************************************************
Function PingArray()
for $loop=3 to ubound($buttonarray0)
$controlname=$buttonarray0[$loop]
$rc=execute("$$commonname = $$$controlname.tooltip")
$rc=execute("$$$controlname.icon=35")
$p=WSHPing($commonname)
if $p[1]=1
$rc=execute("$$$controlname.icon=34")
else
$rc=execute("$$$controlname.icon=33")
; $= $merlin.show()
; $wait = $merlin.speak("$commonname doesn't reply to ping" )
; do sleep 1 until $merlin.wait($wait) <> 0
endif
next
;$= $merlin.hide()
endfunction
function TB($name,$r,$c,$icon)
dim $left, $top
$rc=execute("$$ubound=ubound($$buttonarray$c)+1")
$controlname="Server$ubound" ;? $controlname
$commonname =$name ;? $commonname
$left=($hoff+$hsize)*$r+$row
$top =($vsize+$voff)*$c+$col
$rc=execute('
redim preserve $$ButtonArray$c[$ubound]
$$ButtonArray$c[$r] = "$Controlname"
$$$controlname=$$Form.ToolButton("",$left,$top,$hsize,$vsize)
$$$controlname.icon = $icon
$$$controlname.Tooltip = "$commonname"
$$$controlname.ToggleStyle = 0
$$$controlname.onClick = ""
')
while $top + $vsize + $voff >= $form.clientheight
$form.clientheight=$form.clientheight + 2
loop
while $left + $hsize + $hoff >= $form.clientwidth
$form.clientwidth=$form.clientwidth + 2
loop
if $form.right + $hsize + $hoff >= $Form.screen.width
$Server1.enabled = 0
endif
endfunction
Function Add()
$servername=$form.inputbox("Server Name or IP addr to monitor","Add Server")
if $servername
$nextbutton=ubound($buttonarray0)+1
$=tb($servername,$nextbutton,0,32)
$=writevalue("$KPingerRegKey",$servername,'',Reg_SZ)
endif
endfunction
Function TaskBar()
If @dos=="4.0" $_S="StuckRects" Else $_S="StuckRects2" EndIf
$TaskBar=Val("&"+SubStr(ReadValue("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\$_S","settings"),41,2))
EndFunction
Function end()
quit
endfunction
;****************************************************************************
Function WshPipe($ShellCMD, OPTIONAL $NoEcho)
Dim $WshShell, $oExec, $AllOutput, $Exit, $WshExitCode
$WshErrorMsg=""
$WshShell=CreateObject("WScript.Shell")
$oExec=$WshShell.Exec($ShellCMD)
While $Exit<>1
Dim $Output
Select
Case Not $oExec.StdOut.AtEndOfStream $Output=$oExec.StdOut.ReadAll
Case Not $oExec.StdErr.AtEndOfStream $Output=$oExec.StdErr.ReadAll
$WshErrorMsg = $Output
Case 1 $Output=-1
EndSelect
If $Output=-1
If $oExec.Status=1 $Exit=1 Endif
Else
If $NoEcho<>1 ? $Output Endif
$AllOutput = $AllOutput + $Output
Endif
Loop
$WshExitCode=$oExec.ExitCode
$WshPipe=split($AllOutput,chr(10))
Exit($WshExitCode)
EndFunction
;********************************************************************************************************
FUNCTION WSHPing($Computer,optional $replies)
dim $ip, $l, $r, $count, $return, $line ,$pos, $avg
if not $replies $replies=1 endif
$ip=$computer $Count=0
$shell='%comspec% /c %windir%\system32\ping $Computer -n $replies '
$return=WSHPipe($shell,1)
if not @error
for each $line in $return
select
case instr($line,"[") $l=instr($line,"[")+1
$r=instr($line,"]")
$ip=substr($line,$l,$r-$l)
case instr($line,"reply from") $Count=$Count+1
case instr($line,"Average") $pos=instr($line,"Average")+8
$avg=val(right("$line",len($line)-$pos))
endselect
if instr($line,"timed out") $Count=$Count-1 endif
next
$WSHPing=$ip,$count,$avg
else
$WSHPing="0.0.0.0","0","0"
exit(487)
endif
ENDFUNCTION
|
|
Top
|
|
|
|
|
#91187 - 2003-01-27 03:45 PM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Radimus
Moderator
Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
|
|
|
Top
|
|
|
|
|
#91190 - 2003-01-27 03:49 PM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Radimus
Moderator
Registered: 2000-01-06
Posts: 5187
Loc: Tampa, FL
|
oops... yep... That was my fault.
See what color coding can do ![[Smile]](images/icons/smile.gif)
|
|
Top
|
|
|
|
|
#91196 - 2003-01-28 12:21 AM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
kholm
Korg Regular
Registered: 2000-06-19
Posts: 714
Loc: Randers, Denmark
|
Jooel,
Nice script …
You forgot to explain why macros are not in the keyword list!
My explanation:
Macros are always starting with @ and therefore identified by this in the code.
You miss remmarks on how the code in kix2htm() works:
$f=split(join(split(join(split(join(split(join(split(join(split(join(split($f,"&"),chr(1)), ...
Maybe this script should be made part af an ’advanced’ starters pack in the in the Starters forum. Don’t forget KiXforms.dll (Shawn) and coauthor Jochen
|
|
Top
|
|
|
|
|
#91197 - 2003-01-28 12:30 AM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
Lonkero
KiX Master Guru
Registered: 2001-06-05
Posts: 22346
Loc: OK
|
jochen actually is THE author as he is the father and executive director of this project... and he has strugled with this lot longer
I just coded some lines.
and we may never forget our daddy shawn!
anyway, you quessed right that part why macros are not included.
I would have skipped all the keyword stuff but as kix is as free as it is, there is no-way to differentiate functions from commands.
all though, kixtart inbuild functions do require parameters so they would need brackets... but UDFs don't
but separating macros and vars is pretty easy
only need for macro ref would be to check correct macro names, but that would be syntax-checking.
anyway, skipping the syntax-checking from the engine gave so much more speed that it was a must skip.
thus making the macro-ref unneeded.
advanced starters pack you say?
is there someone to build such a thing ![[Eek!]](images/icons/shocked.gif)
and btw, thanks for stopping by
{edit}
what comes to those remarks or comments about the convertor engine...
I would like to keep the code intact and messed up only by the kix-gurus.
this way, with no comments, it mostlikely will be left alone.
anyway, the complexity and series of join-splits was not my plan...
they just came along when had to keep the engine as fast as possible.
[ 28. January 2003, 06:54: Message edited by: Lonkero ]
_________________________
!download KiXnet
|
|
Top
|
|
|
|
#91202 - 2003-02-18 06:12 AM
Re: PostPrep 1.0 - Quick and easy posting with Syntax Highlighting
|
MCA
KiX Supporter
Registered: 2000-04-28
Posts: 5152
Loc: Netherlands, EU
|
Dear,
The lastest PostPrep 1.0.1 now also on our site as mirror available.
A screen example is
greetings.
btw: Lonkero, we have select an entry thread with most useful information.
|
|
Top
|
|
|
|
Moderator: Shawn, ShaneEP, Ruud van Velsen, Arend_, Jochen, Radimus, Glenn Barnas, Allen, Mart
|
0 registered
and 657 anonymous users online.
|
|
|
![[Roll Eyes]](images/icons/rolleyes.gif){kind=icon}
