code:

---

; -- BBChecker Dependency checker
; -- Based on bbdep.kix from Kent Dyer
; -- Improvements by Patrick Rutten 2002-11-16
; -- Update and signature-file code by Lonkero 2002-11-17
BREAK ON
CLS

; -- Gather reguired fileinfo and show on screen
if not exist(@scriptdir+"\bbDep.sig")
 "no bbDep.sig file found in current dir, can't proceed. @crlf QUITTING..."
 sleep 1
 exit 0
endif
"FILE" at(0,20) "SIZE" at(0,30) "VERSION" ?
$=readprofilestring(@scriptdir+"\bbDep.sig","","")
$files=split(left($,len($)-1),chr(10))
for $=0 to ubound($files)
 $files[$]=$files[$],
  readprofilestring(@scriptdir+"\bbDep.sig",$files[$],"size"),
  readprofilestring(@scriptdir+"\bbDep.sig",$files[$],"version")
 at($+1,0) $files[$][0] at($+1,20) $files[$][1] at($+1,30) $files[$][2]
next

; -- checking the correctness and showing on screen
$bbcheckerdir=readvalue("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion","ProgramFilesPath") + "\BBchecker\"
$=execute("$$bbcheckerdir=$bbcheckerdir")
$kixforms=readvalue("HKEY_CLASSES_ROOT\CLSID\"+readvalue("HKEY_CLASSES_ROOT\Kixtart.Form\CLSID","")+"\InprocServer32","")

for $=0 to ubound($files)
 if "kixforms.dll"=$files[$][0]
  $location=$kixforms
 else
  $location=$bbcheckerdir+$files[$][0]
 endif

 select
 case not exist($location)
  $failure="File Missing"
 case getfileversion($location,"FileVersion")<>$files[$][2]
  $failure="Incorrect FileVersion"
 case getfilesize($location)<> $files[$][1]
  $failure="Incorrect FileSize"
 case 1
  $failure=""
 endselect

 if $failure
  at($+1,40) color r/n $failure
  $err=1
 else
  at($+1,40) color w/n "Passed"
 endif
next

; -- final report
color w/n
IF $err
 at($+1,0)
 ?"Errors occurred!!!"
 ?
 ?"Please download an updated version from"
 ?" - http://www.kixforms.freeuk.com/"
 ?" - http://www.gwspikval.com/jooel/scripts/bbChecker/sources/stable/"
 ?"Or the package from"
 ?" - http://www.gwspikval.com/jooel/scripts/bbChecker/"
 ?
ELSE
 at($+1,0)
 ? "Checker is OK"
 ?
ENDIF

GET $

---

quote:

---

[wkix32.exe]
size="233472"
version="4.12.0.0"

[kixforms.dll]
size="172032"
version="2.1.3.37"

[bbcheckerII.kix]
size="13887"

[pm.kix]
size="517"

[parse.udf]
size="4760"

[slider.udf]
size="1486"

[inst.kix]
size="2667"

[uninst.kix]
size="579"

[bb.ico]
size="3558"

[trash.ico]
size="1142"

[sliderEditor.ico]
size="1406"

---