code:

---

; -- BBChecker Dependency checker
; -- Based on bbdep.kix from Kent Dyer
; -- Improvements by Patrick Rutten 2002-11-16
BREAK ON
CLS

; -- File list
; -- file*size*version
$bbck_files = 
 "bb.ico*3558*Unknown,
 bbCheckerII.kix*13887*Unknown,
 inst.kix*2667*Unknown,
 parse.udf*4760*Unknown,
 pm.kix*517*Unknown,
 slider.udf*Unknown*Unknown,
 sliderEditor.ico*1406*Unknown,
 trash.ico*1142*Unknown,
 uninst.kix*579*Unknown,
 WKIX32.EXE*233472*4.12.0.0,
 KiXforms.dll*172032*2.1.2.36"
 
$bbck_files     = SPLIT($bbck_files,",")
$max_bbck_files = UBOUND($bbck_files)
$windir         = "%windir%"
$systemdrive    = SUBSTR($windir,1,2)
$bbcheckerdir   = $systemdrive + "\Program Files\BBchecker\"
$kixforms       = READVALUE("HKEY_CLASSES_ROOT\CLSID\{F89DF848-618A-46F9-8A1C-396EA442BDD3}\InprocServer32","")
$err            = 0

$i=0

WHILE ($i <= $max_bbck_files)
 $bbck_file = SPLIT($bbck_files[$i],"*")

 IF "Kixforms.dll" = TRIM($bbck_file[0])
  $bbck_file_name = $kixforms
 ELSE
  $bbck_file_name = $bbcheckerdir + TRIM($bbck_file[0])
 ENDIF

 $bbck_file_size = $bbck_file[1]
 $bbck_file_ver  = $bbck_file[2]
 $curver         = GETFILEVERSION($bbck_file_name)

 IF 0 <> INSTR($curver,",")
  $curver = SPLIT($curver,",")  
  $cur    = ""

  IF UBOUND($curver)
   $j = 0
   WHILE $j <= UBOUND($curver)
    $cur = $cur + TRIM($curver[$j])+"."
    $j   = $j + 1
   LOOP
   $cur = SUBSTR($cur,1,LEN($cur)-1)
  ENDIF
 ELSE
  IF "" <> $curver
   $cur = $curver
  ELSE
   $cur = ""
  ENDIF
 ENDIF

 IF (0 = EXIST($bbck_file_name)) OR 
    (GETFILESIZE($bbck_file_name) <> $bbck_file_size AND "Unknown" <> $bbck_file_size) OR
    ($cur <> $bbck_file_ver AND "Unknown" <> $bbck_file_ver)
  ? " - E - " + $bbck_file_name
  $err = 1
 ELSE
  ? " - I - " + $bbck_file_name
 ENDIF
 $i=$i+1
LOOP

IF 0 <> $err
 ? 
 ?"Errors occurred!!!"
 ?
 ?"Some files are missing, have a wrong size or a wrong version"
 ?
 ?"Please download an updated version from"
 ?" - http://www.kixforms.freeuk.com/"
 ?" - http://www.gwspikval.com/jooel/scripts/bbChecker/sources/current/"
 ?"Or the package from"
 ?" - http://www.gwspikval.com/jooel/scripts/bbChecker/"
 ?
ELSE
 ?
 ? "Checker is OK"
 ?
ENDIF

GET $x

---