code:

---

; Kixtart 4.12
; Kixforms 2.1
; Rot13
 
break on
 
$form = createobject("kixtart.form")
$IE=createobject("microsoft.xmlhttp")
$form.text = "Rot13"
$form.fontsize = 10
$form.size=500,400
$form.center
$form.backcolor = skyblue
$url = $form.textbox("Paste URL here",10,10,400,25)
$go = $form.commandbutton("Get",420,10,65,25)
$go.onclick="getPage()"
$text = $form.textbox(,10,40,480,320)
$text.scrollbars=2
$text.wordwrap=1
$text.backcolor = aliceblue
$text.multiline = 1
$form.show
while $form.visible
 $=execute($form.doevents)
loop
 exit 0

function getPage()
$topic=""
$IE.open("GET",$url.text,not 1)
$IE.send
$data=split($IE.responsetext,"posted ")
for $=1 to ubound($data)
	$topic=$topic+left($data[$],instr($data[$]," ")-1)+" By "
	$data[$]=substr($data[$],instr($data[$],"Profile for")+12)
	$topic=$topic+left($data[$],instr($data[$],'"')-1)
	$data[$]=substr($data[$],instr($data[$],'ans-serif">')+11)
	$topic=$topic+@crlf+rot13(join(split(left($data[$],instr($data[$],"</font")-1),"<br />"),@crlf))+@crlf+@crlf
next
$topic=join(split($topic,"<br />"),@crlf)
$text.text=$topic
endfunction

FUNCTION Rot13($s)
DIM $i,$c, $o,$u
$o=SetOption("CaseSensitivity","Off")
$u = (Ubound($s) >=0)
IF $u  $s=Join($s,@CRLF)  ENDIF
FOR $i = 1 TO Len($s)
  $c = Substr($s,$i,1)
  SELECT
    CASE $c >= 'a' AND $c <= 'm'
      $c = Chr(Asc($c)+13)
    CASE $c >= 'n' AND $c <= 'z'
      $c = Chr(Asc($c)-13)
  ENDSELECT
  $Rot13 = $Rot13+$c
NEXT
IF $u  $Rot13 = Split($Rot13,@CRLF)  ENDIF
$o=SetOption("CaseSensitivity",$o)
ENDFUNCTION

---