Jooel,

So, do we want to call our new control a textbox or an editbox ? My vote is editbox because it seems more intuitive. A textbox is for single one-liners and an editbox is for editing large chunks of data. Scrollbars on the editbox - yup - ill put those in as well. OnChange event handling - ill get those in too.

Heres a cool kixforms script - dont necessarily need build 12 for this, just thought it was kinda neat:

code:
break on

$SMALLSTARS = 30
$LARGESTARS = 15

global $smallxpos[$SMALLSTARS]
global $smallypos[$SMALLSTARS]
global $smallspeed[$SMALLSTARS]

global $largexpos[$LARGESTARS]
global $largeypos[$LARGESTARS]
global $largespeed[$LARGESTARS]

$form = createobject("kixtart.form")
$form.caption = "Starfield Simulation"
$form.backcolor = 0 ; black
$form.borderstyle = 2

$width = $form.scalewidth
$height = $form.scaleheight

srnd((-1)*@ticks) ; randomize

For $I = 1 To $SMALLSTARS 
 $SmallXPos[$I] = Rnd($WIDTH)
 $SmallYPos[$I] = Rnd($HEIGHT)
 $SmallSpeed[$I] = RND(5)+1
Next

For $I = 1 To $LARGESTARS 
 $LargeXPos[$I] = Rnd($WIDTH)
 $LargeYPos[$I] = Rnd($HEIGHT)
 $LargeSpeed[$I] = RND(10)+5
Next

$Form.Show

while $form.visible

 $= execute($form.doevents(1))

 $height = $form.scaleheight
 $width = $form.scalewidth

 For $I = 1 To $LARGESTARS
  $Form.ForeColor = 0
  $Form.Rectangle($LargeXPos[$I],$LargeYPos[$I],2,2)
  $LargeXPos[$I] = $LargeXPos[$I] - $LargeSpeed[$I]
  If $LargeXPos[$I] < -10
   $LargeXPos[$I] = $Width
   $LargeYPos[$I] = RND($Height)
   $LargeSpeed[$I] = RND(10)+5
  EndIf
  $Form.ForeColor = &0FFFFFF
  $Form.Rectangle($LargeXPos[$I],$LargeYPos[$I],2,2)
 Next

 For $I = 1 To $SMALLSTARS
  $Form.PSet($SmallXPos[$I],$SmallYPos[$I],0)
  $SmallXPos[$I] = $SmallXPos[$I] - $SmallSpeed[$I]
  If $SmallXPos[$I] < -10
   $SmallXPos[$I] = $Width
   $SmallYPos[$I] = RND($Height)
   $SmallSpeed[$I] = RND(5)+1
  EndIf
  $Form.PSet($SmallXPos[$I],$SmallYPos[$I],&0FFFFFF)
 Next

Loop

Exit 1
Maybe a kixtart screen-saver ? hehee

-Shawn