We are looking at your code. We didn't really find a error, but
you were using an enormous amount of sleep commands and
a lot of GOTO statements.
To prevent unexpected information by undefined @fullname we intro-
duced the variable $fullname.

We have rewritten your code for ideas.

code:

---

 CLS
 ;
 ; Filename: logon.kix
 ; Dit bestand is het login script voor alle gebruikers
 ; op het Domein. Voor Win95 en WinNT
 ;
 ;
 ; Versie Datum: 02-04-2000
 ;
 ; Wijzigings Datum: 05-03-2000
 ; Wijzigings reden: Toevoegen van kleur, stroomlijnen en weghalen van
 ; overbodige variabelen,fout afhandeling bij connecten
 ; van HomeShare.
 ;
 ; Wijzigings Datum: 02-04-2000
 ; Wijzigings reden: extra functies van Kixtart 2001 Beta 1 verstie toevoegen.
 ;
 ;
 SetTitle("Kixtart 2001 "+@kix+" - LogonScript")
 ;
 ;------ Extract Servernaam, mening get rid of the \\ ------
 ;
 $server = Substr(@lserver,Len(@lserver)-6,7)
 ;
 ;------ Detection of daytime ------
 ;
 IF @time >= 18:00:00
       $groet = "Goedenavond"
 ELSE
       IF @time >= 12:00:00
             $groet = "Goedenmiddag"
       ELSE ; - IF @time <= 12:00:00 -
             $groet = "Goedenmorgen"
       ENDIF
 ENDIF
 $user=@userid
 IF (len(@fullname) = 0)
       $fullname = $user
 ELSE
       $fullname = @fullname
 ENDIF
 ;
 ;------ End detection of daytime ------
 ;
 CLS
 SETTIME @lserver
 ?
 ? "De ingestelde tijd op " COLOR y+/n $server COLOR w/n " is " @time 
 SLEEP 2
 ;
 CLS
 ? "--------------------------------------------------------------"
 ?
 ? " Momentje geduld A.U.B."
 ? " U wordt nu op het Domein " COLOR y+/n @domain COLOR w/n " aangekoppeld."
 ?
 ? " Uw Persoonlijke en Gemeenschappelijke"
 ? " directory's worden aangekoppeld."
 ?
 ? " -------------------------------------------------------------"
 SLEEP 2
 ;
 CLS
 ? "--------------------------------------------------------------"
 ?
 ? " " + $groet + " " COLOR c/n $fullname COLOR w/n "."
 ? " U bent aangemeld op "
   COLOR y+/n $server COLOR w/n " op het "
   COLOR y+/n @domain COLOR w/n " Domein."
 ? " Uw gebruikersnaam is "
   COLOR g/n @userid COLOR w/n "."
 ? " Indien bovenstaande gebruikersnaam niet klopt"
 ? " gelieve U kontakt op te nemen met de Helpdesk"
 ?
 ? "--------------------------------------------------------------"
 SLEEP 3
 ;
 ; ------ Remove persistent connections ------
 ;
 IF Exist (@ldrive + "\Kixtart32\RemoveDisks.kix")
       CALL @ldrive + "\Kixtart32\RemoveDisks.kix"
 ELSE
       GOSUB missingscript
 ENDIF
 ;
 ; ------ End remove persistent connections ------
 ; ------ Connecting HomeShare with error handling ------
 ;
 CLS
 IF @homeshr = ""
       ? "--------------------------------------------------------------"
       COLOR b+/n
       ?
       ? " U heeft géén Persoonlijke directory."
       ? " Als dit niet correct is neem dan contact op"
       ? " met de Systeem Beheerder."
       ?
       COLOR w/n
       ? "--------------------------------------------------------------"
       SLEEP 3
 ELSE
       ? " Uw persoonlijke directory wordt nu aangekoppeld ....."
       USE p: @homeshr
       IF @error <> 0
             ? "--------------------------------------------------------------"
             COLOR r+/n
             ?
             ? " Er is iets fout gegaan met het aankoppelen van"
             ? " Uw Persoonlijke directory."
             ? " Systeemmelding is: "+@error+" ("+@serror+")"
             ? " Neem contact op met de Systeem Beheerder."
             ?
             COLOR w/n
             ? "--------------------------------------------------------------"
             SLEEP 3
       ENDIF
 ENDIF
 ;
 ; ------ End connecting HomeShare with error handling ------
 ;
 CLS
 IF (Ingroup("Domeingebruikers") <> 0)
       ? " Uw gezamelijke directory wordt nu aangekoppeld ....."
       USE g: "@LSERVER\Algemeen"
 ENDIF
 IF (Ingroup("Domeinbeheerders") <> 0)
       ? " De MP3 directory wordt nu aangekoppeld ....."
       USE m: "@LSERVER\MP3"
 ENDIF
 ?
 USE list
 SLEEP 3
 ;
 CLS
 ? "------------------------------------------------------------"
 ?
 ? " Beste " COLOR c/n $fullname COLOR w/n "."
 IF @homeshr <> ""
       ? " Onder Driveletter P: vindt U Uw persoonlijke en"
       ? " ALLEEN voor U toegankelijke netwerkdirectory."
 ENDIF
 ? " Onder Driveletter G: vindt U de Data directories"
 ? " van Uw afdeling."
 ?
 ? "------------------------------------------------------------"
 SLEEP 3
 ;
 ; ----- Empty %Temp% Directory ------
 ;
 IF Exist (@ldrive + "\Kixtart32\EmptyDir.kix")
       $dirtoempty = "%Temp%"
       CALL @ldrive + "\Kixtart32\EmptyDir.kix"
       $dirtoempty = ""
 ELSE
       GOSUB missingscript
 ENDIF
 ;
 ; ------- End empty %Temp% Directory ------
 ; ------- Update Procedure ------
 ;
 IF Exist (@ldrive + "\Kixtart32\Update.kix")
       CALL @ldrive + "\Kixtart32\Update.kix"
 ELSE
       GOSUB missingscript
 ENDIF
 GOTO end
 EXIT
 ;
 ; ---------- End Update Procedure ----------
 ; ---------- Missing Script Message ----------
 ;
:missingscript
 ;
 CLS
 $string = "Er is een fout opgetreden. Een onderdeel van"
 $string = $string + Chr(10) + "het Logon Script kon niet worden gevonden."
 $string = $string + Chr(10) + Chr(10) + " Bel de Helpdesk !!!!"
 $selection = MessageBox($string, "Kixtart missing script", 48)
 RETURN
 ;
 ; ---------- End Missing Script Message ----------
 ; ---------- End Logon Script ----------
 ;
:end
 EXIT

---

Greetings.