code:

---

	$server = '192.168.1.2'

	$command = 'cmd /c %windir%\dhcpcmd.exe '+ $server +' getsuperscopetable | find "Subnet address"'
	$superscope = WSHPipe($command,1)

	for each $scope in $superscope
		$subnet = trim(split($scope,'=')[1])
		$command = 'cmd /c %windir%\dhcpcmd.exe '+ $server +' enumclients ' + $subnet+' -h'
		$output = WSHPipe($command,1)
		$x = 0
		For each $line in $output
			if val(left($line,1))
				$arr_IPaddr[$x]   = trim(substr($line,4,15))
				$arr_Computer[$x] = split(trim(substr($line,21,16)),'.')[0]
				$arr_MACaddr[$x]   = trim(substr($line,38,17))
				$x = $x +1
				redim preserve $arr_IPaddr[$x]
				redim preserve $arr_Computer[$x]
				redim preserve $arr_MACaddr[$x]
				endif
			next
		next
	for each $item in $ListViewEx1.items 
		if left($item.SubItems(3).Text,6) = 'Offlin' and $item.subitems(1).text = '¤'
			$Computer = $item.SubItems(2).Text
			$pos = ascan($arr_Computer,$computer)
			if $pos +1
				$mac = $arr_MACaddr[$pos]
				Status("Sending WOL to $computer")
				shell 'cmd /c %windir%\wol.exe ' + $mac +' > nul'
			else
				Status("MAC Addr Not available for $computer")
				endif
			endif
		next
	sleep 15
	endfunction
  

---

quote:

---

The only way of getting the MAC, is either have each PC log it to a central location or collect it from the DHCP server.

---

code:

---

 
BREAK ON
DIM $Computer, $MACAddress

$WMISMSServer = fnWMIConnect("SMSserver",,,,,"/root/sms/site_000")
IF VarType($WMISMSServer) = 9

	for each $Computer in split('wheelerc wheelerc-400 wheelerc-510 wheelerc-LAP')
		$ResourceID = fnSMSGetResourceID($Computer, $WMISMSServer)
		$MACAddress = fnGetMAC($ResourceID)
		? $Computer +'	'+ $MACAddress
		next
ELSE
    ? "NoAccess"
ENDIF



;================================================================
FUNCTION fnWMIConnect(OPTIONAL $sComputer, OPTIONAL $sUSER, OPTIONAL $spwd, OPTIONAL $ImpLevel, OPTIONAL $authLevel, OPTIONAL $sNamespace)
    DIM $locator, $context, $namespace, $moniker
    $moniker	= "winmgmts:{impersonationLevel=impersonate,authenticationLevel=pktPrivacy}!\\"
    $namespace	= iif($sNamespace,$sNamespace,"\root\cimv2")
    IF NOT $sComputer OR $sComputer = "@Wksta" OR $sComputer = "."
        $sComputer = "@Wksta"
        $fnWMIConnect = GetObject($moniker+$sComputer+$namespace)
    ELSE
        IF ($sUSER AND $spwd) OR $sUSER
            IF Substr($namespace, 1, 1) = "\"
                $namespace = Substr($namespace, 2, Len($namespace) - 1)
            ENDIF
            $locator = CreateObject("WbemScripting.SWbemLocator")
            $context = CreateObject("WbemScripting.SWbemNamedValueSet")
            $fnWMIConnect = $locator.ConnectServer($sComputer,$namespace,$sUSER,$spwd,"","",0,$context)
        ELSE
            $fnWMIConnect = GetObject($moniker+$sComputer+$namespace)
        ENDIF
    ENDIF
    IF @Error
        $fnWMIConnect = @SError
    ENDIF
    EXIT @Error
ENDFUNCTION
;================================================================
FUNCTION fnSMSGetResourceID($ComputerName, $WMISMSServerName)
;--- This function will return the Resource ID for a computer from the SMS Server.
    DIM $SMSGetResourceIDError, $SMSGetResourceIDQuery
    $SMSGetResourceIDQuery = 'Select ResourceID from SMS_R_System where Name=' + '"' + $ComputerName + '"'
    $SMSGetResourceIDObjEnumerator = $WMISMSServerName.ExecQuery($SMSGetResourceIDQuery)
    $SMSGetResourceIDError = @Error
    IF $SMSGetResourceIDError <> 0
        $fnSMSGetResourceID = 0
    ELSE
        FOR EACH $SMSGetResourceIDObjInstance IN $SMSGetResourceIDObjEnumerator
           FOR EACH $SMSGetResourceIDOProp IN $SMSGetResourceIDObjInstance.Properties_
             $fnSMSGetResourceID = $SMSGetResourceIDOProp.Value
           NEXT
        NEXT
    ENDIF
    $SMSGetResourceIDObjEnumerator = ''
    EXIT $SMSGetResourceIDError
ENDFUNCTION
;================================================================
FUNCTION fnGetMAC($ComputerResourceID)
    $oClient = $WMISMSServer.ExecQuery ("Select MacAddresses FROM SMS_R_System WHERE ResourceID=" + $ComputerResourceID)
    FOR EACH $Client IN $oClient
        $Index = 0
        FOR EACH $MAC IN $Client.MacAddresses
           $fnGetMAC = Join(Split($Client.MacAddresses($Index), ":", -1), "")
           $Index = $Index + 1
           NEXT
        NEXT
ENDFUNCTION
 

---