This is what I use for our server admin password changes. You'd need to populate the $Servers array with the names of the machines on which you want to change the password. NB You can't change the local admin password on any NT4.0 domain controllers (and though I can't test/prove it, I suspect not on W2k DCs either).

code:
$x = SetOption("wrapateol","on")
? "Please enter the new local administrator password for the domain servers..."
? Gets $pword

Cls

? "Confirm that you wish to change the administrator password on these servers..." ?

$Servers = "Server1","Server2","Server3"


For Each $Server In $Servers
	
	? Ucase($Server) + "		Change password? (y/n)" Get $x
	If Ucase($x) = "Y"
		$ADsUser = GetObject("WinNT://corpdom01/" + $Server + "/administrator,user")
		If @ERROR = 0
			? "ADSI object created OK on " + $Server + "."
		Else
			? "Error creating local administrator object on " + $Server + "."
		Endif
		$ADsUser.SetPassword($pword)
		If @ERROR = 0
			? "Local administrator password set on " + $Server + "."
		Else
			? "Error whilst setting new local administrator password on " + $Server + "."
		Endif
		?
		$ADsUser = 0
	Endif

Next

:end
Exit
You'll also need to have the ADSI runtime files installed on the machine from which you will run this script.

Hope this helps a little.

-Breaker

[ 15. January 2003, 11:41: Message edited by: Breaker ]
_________________________
================================================
Breaker