But if you write to this value in the Registry, you do not have to go through the Internet Explorer Setup Wizard. No IEAK needed, if your users are on LAN/WAN.

If you want to get PSGETSID - http://sysinternals.com/ntw2k/freeware/psgetsid.shtml

Check it out (untested with PSGETSID).

code:

---

$sid = SHELL"psgetsid \\@WKSTA -u @USERID"
$RC = WriteValue("HKEY_USERS\"+$sid+"\Software\Microsoft\Internet Connection Wizard","Completed","01,00,00,00","REG_BINARY")

---

code:

---

$RC = WriteValue("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard","Completed","01,00,00,00","REG_BINARY")

---

What do you think?

- Kent

[ 11 August 2001: Message edited by: kdyer ]

[ 13 August 2001: Message edited by: kdyer ]

[ 13 August 2001: Message edited by: kdyer ]

+ Why not use HKCU and avoid the @SID step?
+ Reg Type is BINARY for my Win2K Pro system,
REG_DWORD for WinNT 4.

Bill

Thanks for the feedback!

- Kent

I updated the script to reflect the REG_BINARY type. It is Binary on W2k as well as NT.

Here is the script as it sits now..

code:

---

;*************************************************************************************
; Pre-Configure Internet Explorer
;*************************************************************************************
$HKCUS = 'HKEY_CURRENT_USER\SOFTWARE'
$IESetup = ReadValue($HKCUS+"\Microsoft\Internet Connection Wizard","Completed")
?$IESetup
If $IESetup <> "01000000"
$RC = WriteValue($HKCUS+"\Microsoft\Internet Connection Wizard","Completed","01,00,00,00","REG_BINARY")
If Exist("%userprofile%"+"\desktop\"+"Connect to the Internet.LNK") Del "%userprofile%"+"\desktop\"+"Connect to the Internet.LNK" EndIf
EndIf

---

Thanks!

- Kent

Here it is:

code:

---

Break ON Cls
;*************************************************************************************
; Pre-Configure Internet Explorer
;*************************************************************************************
$IESetup = ReadValue("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard","Completed")
If $IESetup <> "01000000"
 $ICW=EXISTKEY("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard")
  If $ICW <> 0
   $RC=ADDKEY("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard")
  endif
$RC = WriteValue("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard","Completed","01","REG_BINARY")
If Exist("%userprofile%"+"\desktop\"+"Connect to the Internet.LNK") Del "%userprofile%"+"\desktop\"+"Connect to the Internet.LNK" EndIf
EndIf

---

Thanks!

- Kent

[ 14 August 2001: Message edited by: kdyer ]

[ 14 August 2001: Message edited by: kdyer ]

so, I checked it and ofcourse I had to edit it
I had in mind the speed and most of all, the length of the script part, if needed to add it to existing scripts.

code:

---

;*************************************************************************************
; Pre-Configure Internet Explorer by KDYER
;*************************************************************************************
If "01000000" <> ReadValue("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard","Completed")
	If 0 <> ExistKey("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard")
		$ = AddKey("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard")
	EndIf
	$ = WriteValue("HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard","Completed","01","REG_BINARY")
	If Exist("%userprofile%\desktop\Connect to the Internet.LNK")
		Del "%userprofile%\desktop\Connect to the Internet.LNK"
	EndIf
EndIf
;*************************************************************************************

---

Isn't the same value for this stored under HKCU in Win9x? I believe so...? anyways, a complete Win32 solution could look something like this then:

code:

---

;===============================================================================
;=== Exremely annoying IE stuff fixed by the guys and gals @
;=== http://kixtart.org/cgi-bin/ultimatebb.cgi? 
IF @INWIN = 1
	$IEregKey = "HKEY_USERS\@SID\Software\Microsoft\Internet Connection Wizard"
	$ShortCut = "%USERPROFILE%"
ELSE
	$IEregKey = "HKEY_CURRENT_USER\Software\Microsoft\Internet Connection Wizard"
	$ShortCut = "%WINDIR%"
ENDIF
	
IF "01000000" <> READVALUE("$IEregKey", "Completed")
	IF 0 <> EXISTKEY("$IEregKey")
		$ = ADDKEY("$IEregKey")
	ENDIF
	$ = WRITEVALUE("$IEregKey", "Completed", "01", "REG_BINARY")
	IF EXIST("$ShortCut\Desktop\Connect to the Internet.LNK")
		DEL "$ShortCut\Desktop\Connect to the Internet.LNK"
	ENDIF
	IF EXIST("$ShortCut\Skrivbord\Anslut till Internet.LNK")	; only necessary if u know the true
		DEL "$ShortCut\Skrivbord\Anslut till Internet.LNK"	; meaning of the word "smörgåsbord"  
	ENDIF
ENDIF 

---

?

Cj programmed a special little program for me (nice!) that extracts the contents of *.lnk, making them searchable (so u can find the target string, for example). But this would only slow things up... It's better to make a SELECT CASE if you've got several different OS/IE languages installed, I believe...?

[ 14 August 2001: Message edited by: masken ]

Sweet! Thanks for the insight to the IF Statement..

Mine

code:

---

$IESetup = ReadValue ...

---

Yours

code:

---

If "01000000" <> ReadValue ...

---

Thanks for pointing this out.

I was trying to figure out this methodology using EXISTKEY or KEYEXIST under 2001.. Hmmm..

Maybe something like -

code:

---

IF 1 <> EXISTKEY....

---

Doh!!

- Kent

[ 15 August 2001: Message edited by: kdyer ]

It looks like I was asleep here.

code:

---

$hkcus = 'HKEY_CURRENT_USER\SOFTWARE'
 IF "01000000" <> ReadValue($hkcus+"\Microsoft\Internet Connection Wizard","Completed")
       IF 0 <> EXISTKEY($hkcus+"\Microsoft\Internet Connection Wizard")
             $ = ADDKEY($hkcus+"\Microsoft\Internet Connection Wizard")
       ENDIF
       $ = WriteValue($hkcus+"\Microsoft\Internet Connection Wizard","Completed","01","REG_BINARY")
       IF Exist("%userprofile%"+"\desktop\"+"Connect to the Internet.LNK")
             DEL "%userprofile%"+"\desktop\"+"Connect to the Internet.LNK"
       ENDIF
 ENDIF

---

Thanks!

- Kent