Here is for a prompted install;

shell "\\SERVERNAME\VPHOME\clt-inst\WIN32\setup.exe"

Here is for a silent install;

shell "\\SERVERNAME\VPHOME\clt-inst\WIN32\setup.exe /s /v /qn"

Thanks

i can remember i had this problem with a other programm too. Try to change into the Installfolder with CD and than call the setup.exe.

Maybe it works.

-Brian

more about this kind of quotation mark embedding is in the kix-doc in syntax-rules section.

if this ain't working, I may eat my shorts.

hth

Jochen

[ 06 July 2001: Message edited by: jpols ]

_________________________

[ 06 July 2001: Message edited by: JamesT ]

Thanks

this time you were quicker at the draw ...
Man, in the same minute !!!

Jochen

see you at OK Corral (next post !)

[ 06 July 2001: Message edited by: jpols ]

_________________________

Ok, you found the correct KiX syntax Lonkero [shell '\\SERVERNAME\VPHOME\clt-inst\WIN32\setup.exe /s /v"/qn'+'"']?

The switches for the MSI installer can be found over at Symantec, a doc called How to configure the Norton AntiVirus Corporate Edition 7.5 installation.

another thingie I am unsure of is if this will check for prior 7.x installations, and update those correctly? Has anyone tested this?

I am looking for a way (well.. a piece of KiX code, of course! ) to automatically check the version installed at the client versus the server version, and if an installation is found necessary, display a prompt and then do a Silent Installation. I began this a while back, and haven't actually looked at it at all since then (done it manually..). What do u folks think about this:

code:

---

$IniFile       = "\\[SERVERNAME]\VPHOME\logon\VP_login.ini"
$ClientKey     = "HKEY_LOCAL_MACHINE\SOFTWARE\INTEL\LANDesk\VirusProtect6\CurrentVersion\"
$ClientEntry   = "ProductVersion"
$ServerVersion = READPROFILESTRING("$IniFile", "ClientNumber", "BuildNumber")
IF @ERROR <> 0								; There was an error finding the serverside inifile ($IniFile)
	?" Norton AntiVirus server not available, skipping installation/update check..."
	GOTO End
ELSE
	?" Checking your Norton AntiVirus installation..."
ENDIF
$ClientVersion = READVALUE("$ClientKey", "$ClientEntry")
SELECT
	CASE @ERROR = 2							; Could not find $ClientKey\$ClientEntry...
		$MsgStatus = "installed"					; NAV is NOT installed...
		GOSUB NavUpdate
	CASE @ERROR = 0							; Regkey read successful
		IF INSTR("$ServerVersion", "$ClientVersion") = 0			; strings does NOT match
			$MsgStatus = "updated"				; The client version is different than the server version
			GOSUB NavUpdate
		ELSE
			? " - your Norton AntiVirus is up to date."		; Client version is the same as Server version
		ENDIF
	CASE 1
		? "Unknown error happened while checking "
		? "@@ERROR#@ERROR | @SERROR"
ENDSELECT
:End
EXIT

:NavUpdate
IF @INWIN = 2
	$Message = "Your AntiVirus protection is about to be " + $MsgStatus +
		   ", whereafter the computer will automatically reboot. Please wait for the installation/update to finish."
ELSE
	$Message = "Your AntiVirus protection is about to be " + $MsgStatus +
		   ", whereafter a reboot is recommended. Please wait a minute for the installation/update to finish, and then restart your computer."
ENDIF
$nul = MESSAGEBOX("$Message" ,"Installation message", 0, 10)
SHELL '\\[SERVERNAME]\VPHOME\clt-inst\WIN32\setup.exe /s /v"/qn'+'"'
RETURN

---

The thing is that I want to control which server the client should use, based upon which subnet the client is on. I do this IP check prior to the NAV installation, so all i have to have here is a servername...

And of course it should work with Win9x/NT4/Win200... I dunno about the other thread I found, which uses "vp_log32.exe" (which then calls Setup.exe)...?

Comments? Suggestions? Answers? Please? :P

[ 03 August 2001: Message edited by: masken ]

[ 03 August 2001: Message edited by: masken ]

In your case it would be easy to manually install on one client and see if 7.50 gets uninstalled.

I read up on what 7.51 fixed and decided to stay with 7.50 for now. I'm waiting to see what 7.52 or 7.6 has to offer.

An uninstall example:

code:

---

;  - check if VP5 is installed
;
$vp5uninstall = "C:\Program Files\LANDesk\VP5\vpremove.exe"
$isvp5installed = ReadValue("HKEY_LOCAL_MACHINE\software\microsoft\windows\currentversion\uninstall\ldvp 5.0", "uninstallstring")
if $isvp5installed <> $vp5uninstall goto skipuninstall
endif
if @INWIN = 2
MessageBox("NOTICE!" + Chr(13) + "LANDesk Virus Protect must first be uninstalled." + Chr(13) + "System must REBOOT when complete!" + Chr(13) + "Choose Yes to uninstall and Yes to reboot" + Chr(13) + "on the two options that follow","Norton AntiVirus 7.5 Install",48,60)
RUN "C:\Program Files\LANDesk\VP5\vpremove.exe"
goto finish
endif
RUN "C:\Program Files\LANDesk\VP5\vpremove.exe"
sleep( 1 )
setfocus("Uninstall Message")
sendkeys({ENTER})
sleep( 15 )
setfocus("Uninstall Message")
sendkeys({ENTER})
endif

---

An install example:

code:

---

;emulate vplogon.bat for 32-bit clients
;
if @INWIN = 2
MessageBox("NOTICE!" + Chr(13) + "NAV silent install will run in the background." + Chr(13) + "System will REBOOT automatically when complete!","Norton AntiVirus 7.5 Install",48,60)
else
MessageBox("NAV silent install will run in the background." + Chr(13) + "You may continue working.","Norton AntiVirus 7.5 Install",48,60)
endif
USE L: /DELETE
USE L: "\\FFRAS\vplogon"
SHELL("L:\vp_LOG32 /p=L:")

---

Do you map L:\ and call vp_LOG32 every time a user logs on?

Does this work with NT4/2000 (there was only mention of 9x in the previous thread.. the installer is the same for all Win32 platforms now though, but in my insufficient experience with vp_LOG32, I had to ask )

[ 03 August 2001: Message edited by: masken ]

Masken,
VPLog32.exe is the installer that VPLogon.bat would have called. No this part of the script does not run at every logon. I write the version to the registry and check it to see if install is required.

At the top of the script, I check if installed:

code:

---

$currentbuildver = "7.50.00.846"
$regbuildver = ReadValue("HKEY_LOCAL_MACHINE\software\symantec", "regbuildver")
if $regbuildver = $currentbuildver goto finish endif

---

After the install, I write to the registry:

code:

---

;to make clear that we've been here before
WriteValue("HKEY_LOCAL_MACHINE\software\symantec", "regbuildver",$currentbuildver,"REG_SZ")

---

code:

---

;checking product version number of rvtscan.exe (equals build number)
;if client is NT/2000, $versionNT gets filled with the NAV CE version number
;if client is 9x, $version9X gets filled
;finally, the version number is put in $buildver, independent of the client platform
;
$versionNT = GetFileVersion("c:\program files\navnt\vpc32.exe","ProductVersion")
$version9X = GetFileVersion("c:\program files\norton antivirus\vpc32.exe","ProductVersion")
if $versionNT <> ""
	$buildver = $versionNT
endif
if $version9X <> ""  
	$buildver = $version9X
endif
;
? "NAV CE build " + $buildver
;
;-----------------------------------------------------------------------------------
;we compare the version number of the client to the latest build version
if $buildver = $currentbuildver
        " is up-to-date!"
        ? " " 
        goto finish
else
        " needs updating!"
	? " "
endif

---

I can't take credit for the script as most of it was written by the Original author, Kristof Vermeire. I simply modified to suit.

VPLog32.exe works for all 32 bit platforms, Win9x/NT/2K.

Ah, what the heck, I may as well post the whole script:

code:

---

SETCONSOLE("MINIMIZE")
;-----------------------------------------------------------------------------------
;  Norton Antivirus Corporate Edition 7.x Updater - KiXtart 32
;  version 1.0
;  11-Dec-2000
;  Original author: Kristof Vermeire - kristof.vermeire@azstlucas.be
;  (C) 2000 - AZ Sint-Lucas Hospital Ghent (Belgium)
;
;  Modified by Les Ligetfalvy
;
;-----------------------------------------------------------------------------------
;update is executed only when user is NOT in the global group "NO_NAV"
;this can be left out if everyone should get the update
;
IF INGROUP("NO_NAV") goto finish ENDIF
;-----------------------------------------------------------------------------------
;  check if already installed and if so exit
;
$currentbuildver = "7.50.00.846"
$regbuildver = ReadValue("HKEY_LOCAL_MACHINE\software\symantec", "regbuildver")
if $regbuildver = $currentbuildver goto finish endif
;-----------------------------------------------------------------------------------
;  - check OS WinNT = 1, Win95 = 2
;
if @INWIN = 2 goto OSRightsOK endif
;-----------------------------------------------------------------------------------
;must not be Win95, therefor must be WinNT so more checks are in order
;-----------------------------------------------------------------------------------
;  - check if logon to Server or Workstation
;PRODUCTTYPE - WinNT = Workstation, ServerNT = Member Server, LanmanNT = Domain Controller
;
$PRODUCTTYPE = READVALUE("HKEY_LOCAL_MACHINE\SYSTEM\CURRENTCONTROLSET\CONTROL\PRODUCTOPTIONS","PRODUCTTYPE")
if $PRODUCTTYPE = "WinNT" goto NTwks endif
;
;if logon to server as non-admin, just exit without notice (for WTS users) else nag and exit
;
if INGROUP ("Domain Admins") <> 2 goto finish
beep
MessageBox("NOTICE!" + Chr(13) + "YOU ARE LOGGED ON TO A SERVER, installation aborting!" + Chr(13) + "Maybe you should add yourself to the Global group NO_NAV","Norton AntiVirus 7.5 Install",48,60)
goto finish
ENDIF
;-----------------------------------------------------------------------------------
:NTwks
;  - check if NT User has Local Admin rights
;
if INGROUP ("\\" + @WKSTA + "\Administrators") = 2 goto OSRightsOK
else
beep
MessageBox("NOTICE!" + Chr(13) + "Insufficient rights, installation aborting!" + Chr(13) + "Please notify the FF HelpDesk at ext. 1864","Norton AntiVirus 7.5 Install",48,60)
goto finish
endif
;-----------------------------------------------------------------------------------
:OSRightsOK
;  - check if VP5 is installed
;
$vp5uninstall = "C:\Program Files\LANDesk\VP5\vpremove.exe"
$isvp5installed = ReadValue("HKEY_LOCAL_MACHINE\software\microsoft\windows\currentversion\uninstall\ldvp 5.0", "uninstallstring")
if $isvp5installed <> $vp5uninstall goto skipuninstall
endif
if @INWIN = 2
MessageBox("NOTICE!" + Chr(13) + "LANDesk Virus Protect must first be uninstalled." + Chr(13) + "System must REBOOT when complete!" + Chr(13) + "Choose Yes to uninstall and Yes to reboot" + Chr(13) + "on the two options that follow","Norton AntiVirus 7.5 Install",48,60)
RUN "C:\Program Files\LANDesk\VP5\vpremove.exe"
goto finish
endif
RUN "C:\Program Files\LANDesk\VP5\vpremove.exe"
sleep( 1 )
setfocus("Uninstall Message")
sendkeys({ENTER})
sleep( 15 )
setfocus("Uninstall Message")
sendkeys({ENTER})
endif
;
:skipuninstall
;-----------------------------------------------------------------------------------
;  - check if MS Installer is up-to-date (needed for NAV CE 7.5 and later)
;
;we simply declare the current build level here and use it throughout the script
$currentbuildver = "7.50.00.846"
$returncode = existkey("HKEY_LOCAL_MACHINE\software\symantec")
if $returncode <> 0 addkey("HKEY_LOCAL_MACHINE\software\symantec")
endif
;-----------------------------------------------------------------------------------
;now we prevent the 'double update' by checking our own registry key value
;
$regbuildver = ReadValue("HKEY_LOCAL_MACHINE\software\symantec", "regbuildver")
if $regbuildver = $currentbuildver goto finish endif
;
CLS
;-----------------------------------------------------------------------------------
;checking product version number of rvtscan.exe (equals build number)
;if client is NT/2000, $versionNT gets filled with the NAV CE version number
;if client is 9x, $version9X gets filled
;finally, the version number is put in $buildver, independent of the client platform
;
$versionNT = GetFileVersion("c:\program files\navnt\vpc32.exe","ProductVersion")
$version9X = GetFileVersion("c:\program files\norton antivirus\vpc32.exe","ProductVersion")
if $versionNT <> ""
	$buildver = $versionNT
endif
if $version9X <> ""  
	$buildver = $version9X
endif
;
? "NAV CE build " + $buildver
;
;-----------------------------------------------------------------------------------
;we compare the version number of the client to the latest build version
if $buildver = $currentbuildver
        " is up-to-date!"
        ? " " 
        goto finish
else
        " needs updating!"
	? " "
endif
;
;----------------------------------------------------------------------------------
;if regMSI = 1, we already updated MS Installer
$regMSI = ReadValue("HKEY_LOCAL_MACHINE\software\symantec", "regMSI")
if $regMSI = "1" goto moveon2 endif
;----------------------------------------------------------------------------------
;now we will install the most recent MS Installer build
;
WriteValue("HKEY_LOCAL_MACHINE\software\symantec", "regMSI","1","REG_SZ")
;----------------------------------------------------------------------------------
;creation of network drive map L: => this is \\FFRAS\vplogon
USE L: /DELETE
USE L: "\\FFRAS\vphome"
;run the version specific to the OS
if @INWIN = 2 
SHELL("L:\clt-inst\win32\instmsia.exe /q")
else
SHELL("L:\clt-inst\win32\instmsiw.exe /q")
endif
;
:moveon2
;----------------------------------------------------------------------------------
;we have an older build on the client so we need to perform the update
;beep and emulate vplogon.bat for 32-bit clients
;
beep
if @INWIN = 2
MessageBox("NOTICE!" + Chr(13) + "NAV silent install will run in the background." + Chr(13) + "System will REBOOT automatically when complete!","Norton AntiVirus 7.5 Install",48,60)
else
MessageBox("NAV silent install will run in the background." + Chr(13) + "You may continue working.","Norton AntiVirus 7.5 Install",48,60)
endif
USE L: /DELETE
USE L: "\\FFRAS\vplogon"
SHELL("L:\vp_LOG32 /p=L:")
;
;----------------------------------------------------------------------------------
;we don't want the 'double update', so we write our own registry key value
;to make clear that we've been here before
WriteValue("HKEY_LOCAL_MACHINE\software\symantec", "regbuildver",$currentbuildver,"REG_SZ")
:finish

---