$key = "HKCU\Printers\Connections"
;Enumerate network printers key.
$oldprinters = ArrayEnumKey($key)

For Each $oldprinter in $oldprinters
	;Replace every comma with a backslash
	$oldprinter = Join(Split($oldprinter, ","), "\")
	;Delete each printer that should be deleted.
	$rc = DelPrinterConnection($oldprinter)
Next


;NAME          ArrayEnumKey
;
;ACTION        Creates an array of names of the subkeys contained in a registry key or subkey
;
;AUTHOR        Jens Meyer (sealeopard@usa.net)
;
;VERSION       1.2 (added error codes)
;              1.1
;
;DATE CREATED  2001/12/05
;
;DATE MODIFIED 2003/05/17
;
;KIXTART       4.12+
;
;SYNTAX        ARRAYENUMKEY($subkey)
;
;PARAMETERS    SUBKEY
;              Required string containing the key or subkey for which the subkeys will be enumerated
;
;RETURNS       Array containing the subkeys
;
;REMARKS       none
;
;DEPENDENCIES  none
;
;EXAMPLE       $retcode=arrayenumkey('HKEY_USERS')
;
;KIXTART BBS   http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=get_topic&f=12&t=000064
;
Function arrayenumkey($regsubkey)
	Dim $retcode, $subkeycounter, $currentsubkey, $subkeyarray
	
	If Not KeyExist($regsubkey)
		Exit 87
	EndIf
	
	$subkeycounter = 0
	Do
		$currentsubkey = EnumKey($regsubkey, $subkeycounter)
		If Not @ERROR
			ReDim preserve $subkeyarray[$subkeycounter]
			$subkeyarray[$subkeycounter] = $currentsubkey
			$subkeycounter = $subkeycounter + 1
		EndIf
	Until @ERROR
	
	$arrayenumkey = $subkeyarray
	Exit 0
EndFunction