Hi Nick2 and Welcome to the board.

Just a side note, you should place any code you have between Code Tags, it makes it easier to read and to help you when you need it.
Here is a link that will help you with that. Help

Try this code and let me know if this is what you are looking for.
 Code:
;region Setup Variables
$Version = "Build(1.0.0.1)"
$System = CreateObject("Kixtart.System")
;endregion

Break on
If Not $System
   $= MessageBox("KiXforms Not Initiated. This Script Will Now Close.","Error",16)
   Quit()
EndIf

;region Main Form
$FormA = $System.Form()
$FormA.Text = "Form A " + $Version
$FormA.Size = 600,400
$FormA.SysMenu = 0

$FormBButton = $FormA.Controls.button("Button")
$FormBButton.Width = 120
$FormBButton.Height = 50
$FormBButton.Text = "Form B"
$FormBButton.Top = 10
$FormBButton.Left = 10
$FormBButton.OnClick = "SwitchForms('FormB')"

$FormAQuitButton = $FormA.Controls.button("Button")
$FormAQuitButton.Width = 120
$FormAQuitButton.Height = 50
$FormAQuitButton.Text = "Exit"
$FormAQuitButton.Top = 285
$FormAQuitButton.Left = 10
$FormAQuitButton.OnClick = "ExitForms()"

$FormA.Center
$FormA.Show()

;region Startup
CreateFormB()
;endregion

$Running = 1
While $Running = 1
  $Nul = Execute($FormA.DoEvents())
  $Nul = Execute($FormB.DoEvents())
Loop
Exit 0
;endregion

;region Startup Functions
Function CreateFormB()
  $FormB = $System.Form()  
  $FormB.Text = "Form B " + $Version
  $FormB.Size = 600, 400
  $FormB.SysMenu = 0
  
  $FormAButton = $FormB.Controls.button("Button")
  $FormAButton.Width = 120
  $FormAButton.Height = 50
  $FormAButton.Text = "Form A"
  $FormAButton.Top = 10
  $FormAButton.Left = 10
  $FormAButton.OnClick = "SwitchForms('FormA')"
  
  $FormBButton1 = $FormB.Controls.Button("Button")
  $FormBButton1.Width = 120 
  $FormBButton1.Height = 50 
  $FormBButton1.Text = "1"
  $FormBButton1.Top = 65
  $FormBButton1.Left = 10
  $FormBButton1.OnClick = "OnButtonClick('1')"
  
  $FormBButton2 = $FormB.Controls.Button("Button")
  $FormBButton2.Width = 120 
  $FormBButton2.Height = 50 
  $FormBButton2.Text = "2"
  $FormBButton2.Top = 120
  $FormBButton2.Left = 10
  $FormBButton2.OnClick = "OnButtonClick('2')"
  
  $FormBButton3 = $FormB.Controls.Button("Button")
  $FormBButton3.Width = 120 
  $FormBButton3.Height = 50 
  $FormBButton3.Text = "3"
  $FormBButton3.Top = 175
  $FormBButton3.Left = 10
  $FormBButton3.OnClick = "OnButtonClick('3')"
  
  $FormBButton4 = $FormB.Controls.Button("Button")
  $FormBButton4.Width = 120 
  $FormBButton4.Height = 50 
  $FormBButton4.Text = "4"
  $FormBButton4.Top = 230
  $FormBButton4.Left = 10
  $FormBButton4.OnClick = "OnButtonClick('4')"
  
  $FormBQuitButton = $FormB.Controls.button("Button")
  $FormBQuitButton.Width = 120
  $FormBQuitButton.Height = 50
  $FormBQuitButton.Text = "Exit"
  $FormBQuitButton.Top = 285 
  $FormBQuitButton.Left = 10
  $FormBQuitButton.OnClick = "ExitForms()"
  
EndFunction
;endregion

;region Common Functions
Function SwitchForms($FormName)
  Select
    Case $FormName = "FormA"
      $FormB.Hide
      $FormA.Center
      $FormA.Show()
    Case $FormName = "FormB"
      $FormA.Hide
      $FormB.Center
      $FormB.Show()
  EndSelect
EndFunction

Function OnButtonClick($Button)
  Select
    Case $Button = 1
      ? 'Button 1 Pressed'
    Case $Button = 2
      ? 'Button 2 Pressed'
    Case $Button = 3
      ? 'Button 3 Pressed'
    Case $Button = 4
      ? 'Button 4 Pressed'
  EndSelect
EndFunction

Function ExitForms()
  $Running = 0  
EndFunction
;endregion

_________________________
Wait don't order yet,... get KiXforms Designer .NET 2.0 (Beta)
KiXforms Designer .NET 2.0 (Beta)