Break On
Dim $SO
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('NoMacrosInStrings','On')
 
Dim $ComputerList, $PrinterArray, $Comp, $Printer
$ComputerList = Split('system1,system2,system3,system4,system5',',')
For Each $Comp In $ComputerList
  If $Comp
    $PrinterArray=PrinterList($Comp)
    For Each $Printer In $PrinterArray
      'Computer: ' + $Comp + '  ' + $Printer ?
    Next 
  EndIf
Next
 
Function PrinterList(optional $remotepc, optional $displaymode)
  Dim $service,$printer,$printers,$printerdesc[0],$counter,$portname,$printername
  If $remotepc=""
    $remotepc="."
  EndIf
  $Service = GetObject("winmgmts:\\" + $remotepc + "\root\cimv2")
  If @error
    Exit @error
  EndIf
  $Printers=$service.execquery ('select * from Win32_Printer')
  For Each $printer In $printers
    ReDim Preserve $printerdesc[$counter]
    If $displaymode & 1
      $portname = "," + $printer.portname
    EndIf
    Select
      Case $displaymode & 4 ;remote printers  
        If Left($printer.portname,2)="\\"
          $printername=$printer.name
        EndIf
      Case $displaymode & 2 ;local printers  
        If Left($printer.portname,2)<>"\\"
          $printername=$printer.name
        EndIf
      Case 1 ; all printers  
        $printername=$printer.name
    EndSelect
    If $printername<>""
      $printerdesc[$counter]=$printername + $portname
      $counter=$counter + 1
      $printername=""
    EndIf   
  Next
  $PrinterList=$printerdesc
EndFunction