Well DELTREE is not a valid program on 2000/XP/2003 but the RD command is as I've shown before.

The following code should work just fine on Windows NT/2000/XP/2003 as long as the user has Administrator rights on the system and there are no files locking the profile.
 


 
Break On
Dim $SO
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('NoMacrosInStrings','On')
 
Dim $Profiles,$Profile,$BadProfiles,$File
$Profiles=ExpandEnvironmentVars(ReadValue('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList','ProfilesDirectory'))
'Profiles are stored here: ' + $Profiles ?
$File = '\\szl-fs9ces1\roxio\delete_profiles.txt'
$BadProfiles = ReadFile($File)
'Reading profiles from ' + $File ?
'Read error: ' + @ERROR + '  ' + @SERROR ?
For Each $Profile In $BadProfiles
  If $Profile
    If GetFileAttr($Profiles+'\'+$Profile) & 16
      'Bad Profile found: ' + $Profile ?
      ;Remove the semi-colon from the SHELL line below to actually delete the profile 
      If Len($Profiles+'\'+$Profile)>10
        ;SHELL '%COMSPEC% /C RD /S /Q ' + '"'+$Profiles+'\'+$Profile+'"' 
      EndIf
      'Error removing profile: ' + @ERROR + '  ' + @SERROR ?
    EndIf
  EndIf
Next
 
Function ReadFile($file)
  Dim $lf, $f, $_, $t
  $lf=CHR(10)
  $f=FreeFileHandle
  $_=Open($f,$file)
    If @ERROR Exit @ERROR EndIf
    Do $t=$t+$lf+ReadLine($f) Until @ERROR
    $_=Close($f)
  $ReadFile=Split(SubStr($t,2),$lf)
EndFunction