Quote:

Note: The only information I'd like to gain is the name of the profile folders.



you are just after the Foldernames in the "Documents and Settings" Folder?

while i would be remis to not pimp my own DIRPlus() UDF

here is an example on how to pull this information, and build an array on the fly using Kix's own DIR() command.

(slow day at work for me )

Code:

Break on

;the path To the folder you want To look AT.
$path = "c:\Documents and Settings"

DIM $array[0]	;create our array with a size of 1
DIM $i		;this is Used as a counter To control array size.
DIM $Dir		;this Returns a Value from the Dir() command
DIM $profile	;this is Used To show the contents of $array

;first you need To prime the $Dir variable/command by giving the Dir() comamnd a path
$Dir = Dir($path)

;now enter INTo a Loop, make sure that the $Dir=Dir() 
;is always the last command In the Loop since you are
;relying on the @ERROR from the Dir() To Break the Loop
While not @ERROR
	
	;check To see If the Returnes file/folder is a "Folder"
	If GetFileAttr($path + "\" + $Dir) & 16

		;a quick check To make sure that $Dir Does not equal "." or ".."
		If $Dir = "." or $Dir = ".." 
			;Do not add "." or ".." To $array
		Else
			;$Dir is a "folder" so lets add it To our array
			$array[$i] = $Dir

			;Increase our counter by 1
			$i = $i + 1

			;Increase the size out our array To be able To handle new data
			ReDIM preserve $array[$i]
		EndIf
	EndIf

	$Dir=Dir()
Loop

;the Loop is finished, but our $array has 1 To many pointers In it, so we need To Trim it Down.
;also, If no folder was ever found $i is equal To 0, so In that Case Return nothing
If $i
	ReDIM preserve $array[$i-1]
Else
	;looks like no folders were found, so erasing the $array array
	$array=0
EndIf

;now we have an array that contains all of the folder names In the given path.
For Each $profile In $Array
	? $profile
Next